
theorem Th7:
for n,b being Nat st b > 1 holds value(n-->(b-'1),b) = b|^n - 1
proof
  let n,b be Nat;
  assume A1: b > 1;
  then A2: b-1>1-1 by XREAL_1:14;
  set d=n-->(b-'1);
  set g=(b-'1)(#)(b GeoSeq);
  set d9=g|n;
  A3: dom g=NAT & n in NAT by FUNCT_2:def 1,ORDINAL1:def 12;
  then n c= dom g by ORDINAL1:def 2;
  then A4: dom d9 = dom d by RELAT_1:62;
  A5: for i being Nat st i in dom d9 holds d9.i = (d.i)*(b|^i)
  proof
    let i be Nat;
    assume A6: i in dom d9;
    then A7: i in dom g by A4,A3;
    thus d9.i = g.i by A6,FUNCT_1:47
    .= (b-'1)*((b GeoSeq).i) by A7,VALUED_1:def 5
    .= (d.i)*((b GeoSeq).i) by A6,A4,FUNCOP_1:7
    .= (d.i)*(b|^i) by PREPOWER:def 1;
  end;
  rng d9 c= NAT
  proof
    let o be object;
    assume o in rng d9;
    then consider a being object such that
    A8: a in dom d9 & o=d9.a by FUNCT_1:def 3;
    reconsider a as Nat by A8;
    o=(d.a)*(b|^a) by A8,A5
    .=(b-'1)*(b|^a) by A8,A4,FUNCOP_1:7;
    hence o in NAT by ORDINAL1:def 12;
  end;
  then d9 is NAT-valued by RELAT_1:def 19; then
  reconsider d9 as XFinSequence of NAT by AFINSQ_1:5,A4;
  per cases;
  suppose A9: n=0;
    then n-->(b-'1) = {};
    hence value(n-->(b-'1),b) = 1-1 by Th1 .= b|^n - 1 by A9,NEWTON:4;
  end;
  suppose n<>0;
    then consider m being Nat such that
    A10: n=m+1 by NAT_1:6;
    dom Partial_Sums(b GeoSeq) = NAT by PARTFUN1:def 2;
    then dom ((b-'1)(#)Partial_Sums(b GeoSeq)) = NAT by VALUED_1:def 5;
    then A11: m in dom ((b-'1)(#)Partial_Sums(b GeoSeq)) by ORDINAL1:def 12;
    d9=g|(Segm (m+1)) by A10;
    then Sum d9 = Partial_Sums(g).m by RVSUM_4:4
    .= ((b-'1)(#)Partial_Sums(b GeoSeq)).m by SERIES_1:9
    .= (b-'1)*(Partial_Sums(b GeoSeq).m) by A11,VALUED_1:def 5
    .= (b-'1)*((1 - (b to_power n)) / (1 - b)) by A10,SERIES_1:22,A1
    .= (b-1)*((-((b|^n)-1)) / (-(b-1))) by A2,XREAL_0:def 2
    .= (b-1)*(((b|^n)-1) / (b-1)) by XCMPLX_1:191
    .= b|^n - 1 by XCMPLX_1:87,A2;
    hence value(n-->(b-'1),b) = b|^n - 1 by A4,A5,NUMERAL1:def 1;
  end;
end;
