reserve D for set;
reserve x,x0,x1,x2,y,y0,y1,y2,z,z0,z1,z2,r,s,t for Real;
reserve p,a,u,u0 for Element of REAL 3;
reserve n,m,k for Element of NAT;
reserve f,f1,f2,f3,g for PartFunc of REAL 3,REAL;
reserve R,R1,R2 for RestFunc;
reserve L,L1,L2 for LinearFunc;

theorem Th7:
  for f be PartFunc of REAL 3,REAL for u be Element of REAL 3 holds
  (ex x0,y0,z0 being Real st u = <*x0,y0,z0*> &
  SVF1(1,f,u) is_differentiable_in x0) iff
  f is_partial_differentiable_in u,1
  proof
    let f be PartFunc of REAL 3,REAL;
    let u be Element of REAL 3;
    thus (ex x0,y0,z0 being Real st
    u = <*x0,y0,z0*> & SVF1(1,f,u) is_differentiable_in x0) implies
    f is_partial_differentiable_in u,1 by Th1;
    assume
A1: f is_partial_differentiable_in u,1;
    consider x0,y0,z0 being Element of REAL such that
A2: u = <*x0,y0,z0*> by FINSEQ_2:103;
    proj(1,3).u = x0 by A2,Th1;
    then SVF1(1,f,u) is_differentiable_in x0 by A1;
    hence (ex x0,y0,z0 being Real st u = <*x0,y0,z0*> &
    SVF1(1,f,u) is_differentiable_in x0) by A2;
end;
