
theorem Th7:
  for X being non empty set st 3 c= card X
  for S being TopStruct st
the carrier of S = X & the topology of S = {L where L is Subset of X : 2 = card
  L} holds S is non empty non void non degenerated non truly-partial
  with_non_trivial_blocks identifying_close_blocks without_isolated_points
proof
  let X be non empty set;
  assume
A1: 3 c= card X;
A2: Segm 2 c= Segm 3 by NAT_1:39;
  then 2 c= card X by A1;
  then consider x,y being object such that
A3: x in X & y in X and
A4: x <> y by Th2;
  {x,y} c= X
  by A3,TARSKI:def 2;
  then reconsider l = {x,y} as Subset of X;
  let S be TopStruct;
  assume that
A5: the carrier of S = X and
A6: the topology of S = {L where L is Subset of X : 2 = card L};
  thus S is non empty by A5;
  2 = card l by A4,CARD_2:57;
  then
A7: l in the topology of S by A6;
  then reconsider
  F={L where L is Subset of X : 2 = card L} as non empty set by A6;
  thus S is non void by A7;
  now
    assume X in F;
    then ex L being Subset of X st X=L & 2 = card L;
    then Segm 3 c= Segm 2 by A1;
    hence contradiction by NAT_1:39;
  end;
  then not X is Element of F;
  hence S is non degenerated by A5,A6;
  for x,y being Point of S holds x,y are_collinear
  proof
    let x,y be Point of S;
    per cases;
    suppose
A8:   x=y;
      consider z being object such that
A9:   z in X and
A10:  z <> x by A1,A2,Th3,XBOOLE_1:1;
      reconsider z as Point of S by A5,A9;
A11:  {x,y} c= {x,z}
      proof
        let a be object;
        assume a in {x,y};
        then a=x or a=y by TARSKI:def 2;
        hence thesis by A8,TARSKI:def 2;
      end;
      {x,z} c= X
      proof
        let a be object;
        assume a in {x,z};
        then a = x or a = z by TARSKI:def 2;
        hence thesis by A5;
      end;
      then reconsider l = {x,z} as Subset of X;
      card l = 2 by A10,CARD_2:57;
      then l in the topology of S by A6;
      hence thesis by A11;
    end;
    suppose
A12:  x<>y;
      {x,y} c= X
      proof
        let a be object;
        assume a in {x,y};
        then a=x or a=y by TARSKI:def 2;
        hence thesis by A5;
      end;
      then reconsider l = {x,y} as Subset of X;
      card {x,y} = 2 by A12,CARD_2:57;
      then l in the topology of S by A6;
      hence thesis;
    end;
  end;
  hence S is non truly-partial;
  thus S is with_non_trivial_blocks
  proof
    let k be Block of S;
    k in the topology of S by A7;
    then ex m being Subset of X st m = k & card m = 2 by A6;
    hence thesis;
  end;
  thus S is identifying_close_blocks
  proof
    let k,l be Block of S;
    assume 2 c= card(k /\ l);
    then consider a,b being object such that
A13: a in k /\ l & b in k /\ l and
A14: a <> b by Th2;
A15: {a,b} c= k /\ l
    by A13,TARSKI:def 2;
    l in the topology of S by A7;
    then
A16: ex n being Subset of X st n = l & card n = 2 by A6;
    then reconsider l1=l as finite set;
A17: k /\ l c= l1 by XBOOLE_1:17;
    k in the topology of S by A7;
    then
A18: ex m being Subset of X st m = k & card m = 2 by A6;
    then reconsider k1=k as finite set;
A19: card {a,b} = 2 by A14,CARD_2:57;
    k /\ l c= k1 by XBOOLE_1:17;
    then {a,b} = k1 by A18,A15,A19,CARD_2:102,XBOOLE_1:1;
    hence thesis by A15,A19,A16,A17,CARD_2:102,XBOOLE_1:1;
  end;
  thus S is without_isolated_points
  proof
    let x be Point of S;
    consider z being object such that
A20: z in X and
A21: z <> x by A1,A2,Th3,XBOOLE_1:1;
    {x,z} c= X
    proof
      let a be object;
      assume a in {x,z};
      then a=x or a=z by TARSKI:def 2;
      hence thesis by A5,A20;
    end;
    then reconsider l = {x,z} as Subset of X;
    card {x,z} = 2 by A21,CARD_2:57;
    then l in the topology of S by A6;
    then reconsider l as Block of S;
    take l;
    thus thesis by TARSKI:def 2;
  end;
end;
