
theorem Th7:
  for CPNT1,CPNT2 be Colored_Petri_net, t1 be transition of CPNT1,
  t2 be transition of CPNT2 st the carrier of CPNT1 c= the carrier of CPNT2
   & the
  S-T_Arcs of CPNT1 c= the S-T_Arcs of CPNT2 & the T-S_Arcs of CPNT1 c= the
  T-S_Arcs of CPNT2 & t1=t2 holds *'{t1} c= *'{t2} & {t1}*' c= {t2}*'
proof
  let CPNT1,CPNT2 be Colored_Petri_net, t1 be transition of CPNT1,t2 be
  transition of CPNT2;
  assume that
A1: the carrier of CPNT1 c= the carrier of CPNT2 and
A2: the S-T_Arcs of CPNT1 c= the S-T_Arcs of CPNT2 and
A3: the T-S_Arcs of CPNT1 c= the T-S_Arcs of CPNT2 and
A4: t1=t2;
  thus *'{t1} c= *'{t2}
  proof
    let x be object;
    assume
A5: x in *'{t1};
    then
A6: x is place of CPNT2 by A1;
    ex s be place of CPNT1 st x=s & ex f being S-T_arc of CPNT1, w being
    transition of CPNT1 st w in {t1 } & f = [s,w] by A5;
    then consider
    f being S-T_arc of CPNT1, w being transition of CPNT1 such that
A7: w in {t2} and
A8: f = [x,w] by A4;
    f is S-T_arc of CPNT2 by A2;
    hence thesis by A7,A8,A6;
  end;
  let x be object;
  assume
A9: x in {t1}*';
  then
A10: x is place of CPNT2 by A1;
  ex s be place of CPNT1 st x=s & ex f being T-S_arc of CPNT1, w being
  transition of CPNT1 st w in { t1} & f = [w,s] by A9;
  then consider
  f being T-S_arc of CPNT1, w being transition of CPNT1 such that
A11: w in {t2} and
A12: f = [w,x] by A4;
  f is T-S_arc of CPNT2 by A3;
  hence thesis by A11,A12,A10;
end;
