
theorem Th7:
  for f,m,k be Nat st m >= 1 & k >= 2 & f needs_digits_of m,k holds
  f >= SDDec(Fmin(m+2,m,k))
proof
  let f,m,k be Nat;
  assume that
A1: m >= 1 and
A2: k >= 2 and
A3: f needs_digits_of m,k;
  for i be Nat st i in Seg m holds DigA(DecSD(f,m,k),i) >= DigA(Fmin(m,m,k ),i)
  proof
    let i be Nat;
    assume
A4: i in Seg m;
    then
A5: i <= m by FINSEQ_1:1;
    now
      per cases by A5,XXREAL_0:1;
      suppose
A6:     i = m;
        then DigA(DecSD(f,m,k),i) > 0 by A1,A3,Th6;
        then
A7:     DigA(DecSD(f,m,k),i) >= 0 + 1 by INT_1:7;
        DigA(Fmin(m,m,k),i) = FminDigit(m,k,i) by A4,RADIX_5:def 6
          .= 1 by A2,A6,RADIX_5:def 5;
        hence thesis by A7;
      end;
      suppose
A8:     i < m;
        DigA(Fmin(m,m,k),i) = FminDigit(m,k,i) by A4,RADIX_5:def 6
          .= 0 by A2,A8,RADIX_5:def 5;
        hence thesis by A4,Th5;
      end;
    end;
    hence thesis;
  end;
  then SDDec(DecSD(f,m,k)) >= SDDec(Fmin(m,m,k)) by A1,RADIX_5:13;
  then
A9: SDDec(DecSD(f,m,k)) >= SDDec(Fmin(m+2,m,k)) by A1,A2,Th1;
  f < (Radix(k) |^ m) by A3;
  then f is_represented_by m,k by RADIX_1:def 12;
  hence thesis by A1,A9,RADIX_1:22;
end;
