reserve x for object, X,Y for set;
reserve C for non empty set;
reserve c for Element of C;
reserve f,f1,f2,f3,g,g1 for complex-valued Function;
reserve r,p for Complex;

theorem Th7:
  r<>0 implies (r(#)f)"{0} = f"{0}
proof
  assume
A1: r<>0;
  now
    let c be object;
    reconsider cc = c as object;
    thus c in (r(#)f)"{0} implies c in f"{0}
    proof
      assume
A2:   c in (r(#)f)"{0};
      then
A3:   c in dom (r(#)f) by FUNCT_1:def 7;
      (r(#)f).c in {0} by A2,FUNCT_1:def 7;
      then (r(#)f).c = 0 by TARSKI:def 1;
      then r*f.cc = 0 by A3,VALUED_1:def 5;
      then f.c = 0 by A1;
      then
A4:   f.c in {0} by TARSKI:def 1;
      c in dom f by A3,VALUED_1:def 5;
      hence thesis by A4,FUNCT_1:def 7;
    end;
    assume
A5: c in (f)"{0};
    then f.c in {0} by FUNCT_1:def 7;
    then f.c = 0 by TARSKI:def 1;
    then
A6: r*f.cc = 0;
A7: c in dom f by A5,FUNCT_1:def 7;
    then c in dom (r(#)f) by VALUED_1:def 5;
    then (r(#)f).c = 0 by A6,VALUED_1:def 5;
    then
A8: (r(#)f).c in {0} by TARSKI:def 1;
    c in dom (r(#)f) by A7,VALUED_1:def 5;
    hence c in (r(#)f)"{0} by A8,FUNCT_1:def 7;
  end;
  hence thesis by TARSKI:2;
end;
