reserve x for set,
  i for Instruction of SCM+FSA,
  a,b for Int-Location,
  f for FinSeq-Location,
  l, l1 for Nat,
  s,s1,s2 for State of SCM+FSA,
  P,P1,P2 for Instruction-Sequence of SCM+FSA;

theorem Th6:
  for I being keeping_0 parahalting really-closed Program of SCM+FSA,
      j being sequential Instruction of SCM+FSA
   holds IExec(I ";" j,P,s).f = Exec(j,IExec(I,P,s)).f
proof
  let I be keeping_0 parahalting really-closed Program of SCM+FSA,
      j be sequential Instruction of SCM+FSA;
  set Mj = Macro j;
  set SA = Start-At (IC IExec(Mj,P,IExec(I,P,s)) + card I,SCM+FSA);
A1: not f in dom SA by SCMFSA_2:103;
A2: DataPart Initialized IExec(I,P,s) = DataPart IExec(I,P,s) by Lm2;
  f in FinSeq-Locations by SCMFSA_2:def 5;
  then
A3: f in Data-Locations SCM+FSA by SCMFSA_2:100,XBOOLE_0:def 3;
  thus IExec(I ";" j,P,s).f = IncIC(IExec(Mj,P,IExec(I,P,s)),card I).f
           by SCMFSA6B:20
    .= IExec(Mj,P,IExec(I,P,s)).f by A1,FUNCT_4:11
    .= ( Exec(j, Initialized IExec(I,P,s))).f by Th4
    .= (DataPart Exec(j, Initialized IExec(I,P,s))).f by A3,FUNCT_1:49
    .= (DataPart Exec(j,IExec(I,P,s))).f by A2,Th3
    .= Exec(j,IExec(I,P,s)).f by A3,FUNCT_1:49;
end;
