reserve A,B,C for Ordinal,
        o for object,
        x,y,z,t,r,l for Surreal,
        X,Y for set;

theorem Th7:
  -x = [-- R_x, --L_x]
proof
  set A= born x;
  consider S be c=-monotone Function-yielding Sequence such that
  A1:dom S = succ A & No_opposite_op A = S.A and
  A2:for B be Ordinal st B in succ A
         ex SB be ManySortedSet of Day B st S.B = SB &
           for x be object st x in Day B holds
             SB.x = [union rng (S|B).:R_x, union rng(S|B).:L_x] by Def2;
  consider SA be ManySortedSet of Day A such that
  A3:S.A = SA and
  A4:for x be object st x in Day A holds
       SA.x = [union rng (S|A).:R_x, union rng(S|A).:L_x]
       by A2,ORDINAL1:6;
  set U = union rng (S|A);
  x in Day A by SURREAL0:def 18;
  then A5: [U.:R_x, U.:L_x] = -x by A1,A3,A4;
  A6: -- R_x c= U.:R_x
  proof
    let y be object such that A7: y in -- R_x;
    consider a be Surreal such that
    A8:a in R_x & y = -a by Def4,A7;
    set B = born a;
    A9:  a in L_x\/ R_x by A8,XBOOLE_0:def 3;
    then A10: B in A by SURREALO:1;
    A11:B in succ A by A9,SURREALO:1,ORDINAL1:8;
    then consider SB be ManySortedSet of Day B such that
    A12:S.B = SB and
    for x be object st x in Day B holds
    SB.x = [union rng (S|B).:R_x, union rng(S|B).:L_x] by A2;
    A13:No_opposite_op B = S.B by A11,A1,A2,Th4;
    A14: dom SB = Day B by PARTFUN1:def 2;
    A15: a in Day B by SURREAL0:def 18;
    A16:SB.a = (union rng S).a by Th2,A12,A14,A15,A11,A1;
    (union rng S).a = U.a & a in dom U
    by Th5,A10,A14,A15,A12;
    hence thesis by FUNCT_1:def 6,A8,A16,A13,A12;
  end;
  U.:R_x c= -- R_x
  proof
    let y be object such that A17: y in U.:R_x;
    consider a be object such that
    A18: a in dom U & a in R_x & U.a = y by A17,FUNCT_1:def 6;
    reconsider a as Surreal by A18,SURREAL0:def 16;
    set B = born a;
    A19: a in L_x\/ R_x by A18,XBOOLE_0:def 3;
    then A20: B in A by SURREALO:1;
    A21:B in succ A by SURREALO:1,A19,ORDINAL1:8;
    then consider SB be ManySortedSet of Day B such that
    A22:S.B = SB and
      for x be object st x in Day B holds
        SB.x = [union rng (S|B).:R_x, union rng(S|B).:L_x] by A2;
    A23:No_opposite_op B = S.B by A21,A1,A2,Th4;
    A24:  dom SB = Day B by PARTFUN1:def 2;
    A25: a in Day B by SURREAL0:def 18;
    SB.a = (union rng S).a by Th2,A24,A25,A21,A22,A1;
    then -a = y by A18,Th5,A20,A23,A24,A25,A22;
    hence thesis by A18,Def4;
  end;
  then A26: U.:R_x  = -- R_x by A6,XBOOLE_0:def 10;
  A27: -- L_x c= U.:L_x
  proof
    let y be object such that A28: y in -- L_x;
    consider a be Surreal such that
    A29:a in L_x & y = -a by Def4,A28;
    set B = born a;
    A30:  a in L_x\/ R_x by A29,XBOOLE_0:def 3;
    then A31: B in A by SURREALO:1;
    A32:B in succ A by A30,SURREALO:1,ORDINAL1:8;
    then consider SB be ManySortedSet of Day B such that
    A33:S.B = SB and
      for x be object st x in Day B holds
        SB.x = [union rng (S|B).:R_x, union rng(S|B).:L_x] by A2;
    A34:No_opposite_op B = S.B by A32,A1,A2,Th4;
    A35:dom SB = Day B by PARTFUN1:def 2;
    A36:a in Day B by SURREAL0:def 18;
    A37:SB.a = (union rng S).a by Th2,A33,A35,A36,A32,A1;
    (union rng S).a = U.a & a in dom U by Th5,A31,A35,A36,A33;
    hence thesis by FUNCT_1:def 6,A29,A37,A34,A33;
  end;
  U.:L_x c= -- L_x
  proof
    let y be object such that A38: y in U.:L_x;
    consider a be object such that
    A39: a in dom U & a in L_x & U.a = y by A38,FUNCT_1:def 6;
    reconsider a as Surreal by A39,SURREAL0:def 16;
    set B = born a;
    A40: a in L_x\/ R_x by A39,XBOOLE_0:def 3;
    then A41: B in A by SURREALO:1;
    A42:B in succ A by SURREALO:1,A40,ORDINAL1:8;
    then consider SB be ManySortedSet of Day B such that
    A43:S.B = SB and
      for x be object st x in Day B holds
        SB.x = [union rng (S|B).:R_x, union rng(S|B).:L_x] by A2;
    A44:No_opposite_op B = S.B by A42,A1,A2,Th4;
    A45:dom SB = Day B by PARTFUN1:def 2;
    A46:a in Day B by SURREAL0:def 18;
    SB.a = (union rng S).a by Th2,A45,A46,A42,A43,A1;
    then -a = y by A39,Th5,A41,A44,A45,A46,A43;
    hence thesis by A39,Def4;
  end;
  hence thesis by A5,A26,A27,XBOOLE_0:def 10;
end;
