reserve T for TopSpace;

theorem Th7:
  for F being Subset-Family of T holds Cl F = {A where A is Subset
  of T : ex B being Subset of T st A = Cl B & B in F}
proof
  let F be Subset-Family of T;
  set P = {A where A is Subset of T : ex B being Subset of T st A = Cl B & B
  in F};
  now
    let C be object;
    assume C in P;
    then
    ex A being Subset of T st C = A & ex B being Subset of T st A = Cl B &
    B in F;
    hence C in bool the carrier of T;
  end;
  then reconsider P as Subset-Family of T by TARSKI:def 3;
  reconsider P as Subset-Family of T;
  for X being object holds X in Cl F iff X in P
  proof
    let X be object;
A1: now
      assume
A2:   X in P;
      then reconsider C = X as Subset of T;
      ex D being Subset of T st D = C & ex B being Subset of T st D = Cl
      B & B in F by A2;
      hence X in Cl F by PCOMPS_1:def 2;
    end;
    now
      assume
A3:   X in Cl F;
      then reconsider C = X as Subset of T;
      ex B being Subset of T st C = Cl B & B in F by A3,PCOMPS_1:def 2;
      hence X in P;
    end;
    hence thesis by A1;
  end;
  hence thesis by TARSKI:2;
end;
