reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem Th77:
  for V being ComplexLinearSpace, L being C_Linear_Combination of
  V st L is convex holds Carrier L <> {}
proof
  let V be ComplexLinearSpace;
  let L be C_Linear_Combination of V;
  assume L is convex;
  then consider F being FinSequence of the carrier of V such that
A1: F is one-to-one & rng F = Carrier L and
A2: ex f being FinSequence of REAL st len f = len F & Sum f = 1 & for n
  being Nat st n in dom f holds f.n = L.(F.n) & f.n >= 0;
 consider f being FinSequence of REAL such that
A3:  len f = len F & Sum f = 1 & for n
  being Nat st n in dom f holds f.n = L.(F.n) & f.n >= 0 by A2;
  assume Carrier L = {};
  then len F = 0 by A1,CARD_1:27,FINSEQ_4:62;
  then f = <*>the carrier of V by A3;
  hence contradiction by A3,RVSUM_1:72;
end;
