reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th80:
  for G being strict GroupWithOperators of O, N being strict
  normal StableSubgroup of G, H being strict StableSubgroup of G./.N st the
  carrier of G = (nat_hom N)"(the carrier of H) holds H = (Omega).(G./.N)
proof
  let G be strict GroupWithOperators of O;
  let N be strict normal StableSubgroup of G;
  reconsider N9 = the multMagma of N as strict normal Subgroup of G by Lm6;
  let H be strict StableSubgroup of G./.N;
  reconsider H9 = the multMagma of H as strict Subgroup of G./.N by Lm15;
A1: the carrier of H9 c= the carrier of G./.N & the multF of H9 = (the multF
  of G./.N)||the carrier of H9 by GROUP_2:def 5;
  the carrier of G./.N = the carrier of G./.N9 & the multF of G./.N = the
  multF of G./.N9 by Def14,Def15;
  then reconsider H9 as strict Subgroup of G./.N9 by A1,GROUP_2:def 5;
  assume the carrier of G = (nat_hom N)"(the carrier of H);
  then
A2: the carrier of G = (nat_hom N9)"(the carrier of H9) by Def20;
  now
    reconsider R = nat_hom N9 as Relation of the carrier of G, the carrier of
    G./.N9;
    let h be Element of G./.N9;
    thus h in H9 implies h in (Omega).(G./.N9) by STRUCT_0:def 5;
    assume h in (Omega).(G./.N9);
    h in Left_Cosets N9;
    then consider g be Element of G such that
A3: h = g * N9 by GROUP_2:def 15;
    consider h9 be Element of G./.N9 such that
A4: [g,h9] in R and
A5: h9 in (the carrier of H9) by A2,RELSET_1:30;
    (nat_hom N9).g = h9 by A4,FUNCT_1:1;
    then h in the carrier of H9 by A3,A5,GROUP_6:def 8;
    hence h in H9 by STRUCT_0:def 5;
  end;
  then H9 = (Omega).(G./.N9);
  then the carrier of H = Cosets N by Def14;
  hence thesis by Lm4;
end;
