
theorem Th80:
  for p1,p2,p3,p4 being Point of TOP-REAL 2, a,b,c,d being Real
, f,g being Function of I[01],TOP-REAL 2 st a<b & c < d & p1`1=a & p2`1=a
& p3`2=d & p4`2= c & c <=p1`2 & p1`2<p2`2 & p2`2<=d & a<=p3`1 & p3`1<=b & a <p4
`1 & p4`1<=b & f.0=p1 & f.1=p3 & g.0=p2 & g.1=p4 & f is continuous one-to-one &
g is continuous one-to-one & rng f c= closed_inside_of_rectangle(a,b,c,d) & rng
  g c= closed_inside_of_rectangle(a,b,c,d) holds rng f meets rng g
proof
  reconsider O=0,I=1 as Point of I[01] by BORSUK_1:40,XXREAL_1:1;
  let p1,p2,p3,p4 be Point of TOP-REAL 2, a,b,c,d be Real, f,g be
  Function of I[01],TOP-REAL 2;
  assume that
A1: a<b and
A2: c < d and
A3: p1`1=a and
A4: p2`1=a and
A5: p3`2=d and
A6: p4`2= c and
A7: c <=p1`2 and
A8: p1`2<p2`2 and
A9: p2`2<=d and
A10: a<=p3`1 and
A11: p3`1<=b and
A12: a <p4`1 and
A13: p4`1<=b and
A14: f.0=p1 and
A15: f.1=p3 and
A16: g.0=p2 and
A17: g.1=p4 and
A18: f is continuous one-to-one and
A19: g is continuous one-to-one and
A20: rng f c= closed_inside_of_rectangle(a,b,c,d) and
A21: rng g c= closed_inside_of_rectangle(a,b,c,d);
  set A=2/(b-a), B=-(b+a)/(b-a), C = 2/(d-c), D=-(d+c)/(d-c);
  set h=AffineMap(A,B,C,D);
  reconsider g2= h*g as Function of I[01],TOP-REAL 2;
A22: -1<((g2).I)`1 by A1,A2,A6,A12,A13,A17,Th61;
A23: ((g2).I)`1<=1 by A1,A2,A6,A12,A13,A17,Th61;
A24: g2 is continuous one-to-one by A1,A2,A19,Th53;
A25: ((g2).I)`2= -1 by A2,A6,A17,Th57;
A26: ((g2).O)`1= -1 by A1,A4,A16,Th54;
A27: rng (g2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A21,Th52;
  d-c >0 by A2,XREAL_1:50;
  then
A28: C >0 by XREAL_1:139;
  reconsider f2= h*f as Function of I[01],TOP-REAL 2;
A29: -1<=((f2).I)`1 by A1,A2,A5,A10,A11,A15,Th59;
A30: rng (f2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A20,Th52;
A31: ((f2).I)`2= 1 by A2,A5,A15,Th55;
  p1`2<=d by A8,A9,XXREAL_0:2;
  then
A32: -1 <=((f2).O)`2 by A1,A2,A3,A7,A14,Th59;
A33: ((f2).O)`1= -1 by A1,A3,A14,Th54;
A34: f2 is continuous one-to-one by A1,A2,A18,Th53;
A35: ((f2).I)`1<=1 by A1,A2,A5,A10,A11,A15,Th59;
  set x = the Element of rng f2 /\ rng g2;
A36: dom g=the carrier of I[01] by FUNCT_2:def 1;
  then
A37: h.p2=g2.O by A16,FUNCT_1:13;
A38: (g.I)`2= c by A6,A17;
  c <p2`2 by A7,A8,XXREAL_0:2;
  then
A39: ((g2).O)`2<=1 by A1,A2,A9,A12,A13,A16,A17,A38,Th61;
  b-a>0 by A1,XREAL_1:50;
  then
A40: A >0 by XREAL_1:139;
  then
A41: (h.p1)`2<(h.p2)`2 by A8,A28,Th51;
A42: dom f=the carrier of I[01] by FUNCT_2:def 1;
  then h.p1=f2.O by A14,FUNCT_1:13;
  then rng f2 meets rng g2 by A41,A37,A34,A33,A31,A32,A29,A35,A30,A24,A26,A25
,A39,A22,A23,A27,Th20,JGRAPH_6:79;
  then
A43: rng f2 /\ rng g2 <>{} by XBOOLE_0:def 7;
  then x in rng g2 by XBOOLE_0:def 4;
  then consider z2 being object such that
A44: z2 in dom g2 and
A45: x=g2.z2 by FUNCT_1:def 3;
A46: x=h.(g.z2) by A36,A44,A45,FUNCT_1:13;
  h is being_homeomorphism by A40,A28,Th51;
  then
A47: h is one-to-one by TOPS_2:def 5;
  x in rng f2 by A43,XBOOLE_0:def 4;
  then consider z1 being object such that
A48: z1 in dom f2 and
A49: x=f2.z1 by FUNCT_1:def 3;
A50: f.z1 in rng f by A42,A48,FUNCT_1:def 3;
A51: g.z2 in rng g by A36,A44,FUNCT_1:def 3;
  g.z2 in the carrier of TOP-REAL 2 by A44,FUNCT_2:5;
  then
A52: g.z2 in dom h by FUNCT_2:def 1;
  f.z1 in the carrier of TOP-REAL 2 by A48,FUNCT_2:5;
  then
A53: f.z1 in dom h by FUNCT_2:def 1;
  x=h.(f.z1) by A42,A48,A49,FUNCT_1:13;
  then f.z1=g.z2 by A46,A53,A52,A47,FUNCT_1:def 4;
  hence thesis by A50,A51,XBOOLE_0:3;
end;
