reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem
  for f be PartFunc of the carrier of CNS,COMPLEX st dom f is compact &
  f is_continuous_on (dom f) holds (rng f) is compact
proof
  let f be PartFunc of the carrier of CNS,COMPLEX;
  assume that
A1: dom f is compact and
A2: f is_continuous_on (dom f);
  now
    let s1 be Complex_Sequence such that
A3: rng s1 c= rng f;
    defpred P[set,set] means $2 in dom f & f/.$2=s1.$1;
A4: for n ex p be Point of CNS st P[n,p]
    proof
      let n;
      dom s1 = NAT by FUNCT_2:def 1;
      then s1.n in rng s1 by FUNCT_1:3;
      then consider p be Point of CNS such that
A5:   p in dom f & s1.n = f.p by A3,PARTFUN1:3;
      take p;
      thus thesis by A5,PARTFUN1:def 6;
    end;
    consider q1 be sequence of CNS such that
A6: for n holds P[n,q1.n]from FUNCT_2:sch 3(A4);
    now
      let x be object;
      assume x in rng q1;
      then consider n being Nat such that
A7:     x = q1.n by Th7;
       n in NAT by ORDINAL1:def 12;
      hence x in dom f by A6,A7;
    end;
    then
A8: rng q1 c= dom f;
    then consider s2 be sequence of CNS such that
A9: s2 is subsequence of q1 and
A10: s2 is convergent and
A11: (lim s2) in dom f by A1;
    take q2 = f/*s2;
    rng s2 c= rng q1 by A9,VALUED_0:21;
    then
A12: rng s2 c= dom f by A8;
    now
      let n;
      f/.(q1.n)=s1.n by A6;
      hence (f/*q1).n= s1.n by A8,FUNCT_2:109;
    end;
    then
A13: f/*q1=s1 by FUNCT_2:63;
    f|(dom f) is_continuous_in (lim s2) by A2,A11;
    then
A14: f is_continuous_in (lim s2) by RELAT_1:68;
    then f/.(lim s2) = lim (f/*s2) by A10,A12;
    hence
    q2 is subsequence of s1 & q2 is convergent & (lim q2) in rng f by A8,A13,A9
,A10,A14,A12,PARTFUN2:2,VALUED_0:22;
  end;
  hence thesis by CFCONT_1:def 3;
end;
