reserve n,m,k for Nat,
  x,X for set,
  A for Subset of X,
  A1,A2 for SetSequence of X;

theorem Th80:
  A1 is convergent implies lim_inf (A (\+\) A1) = A \+\ lim_inf A1
proof
  assume
A1: A1 is convergent;
  thus lim_inf (A (\+\) A1) c= A \+\ lim_inf A1 by Th78;
  thus A \+\ lim_inf A1 c= lim_inf (A (\+\) A1)
  proof
    let x be object;
    assume
A2: x in A \+\ lim_inf A1;
    per cases by A2,XBOOLE_0:1;
    suppose
A3:   x in A & not x in lim_inf A1;
      then not x in lim_sup A1 by A1,KURATO_0:def 5;
      then consider n1 being Nat such that
A4:   for k holds not x in A1.(n1+k) by KURATO_0:5;
      now
        let k;
        not x in A1.(n1+k) by A4;
        then x in A \+\ A1.(n1+k) by A3,XBOOLE_0:1;
        hence x in (A (\+\) A1).(n1+k) by Def9;
      end;
      hence thesis by KURATO_0:4;
    end;
    suppose
A5:   not x in A & x in lim_inf A1;
      then consider n2 being Nat such that
A6:   for k holds x in A1.(n2+k) by KURATO_0:4;
      now
        let k;
        x in A1.(n2+k) by A6;
        then x in A \+\ A1.(n2+k) by A5,XBOOLE_0:1;
        hence x in (A (\+\) A1).(n2+k) by Def9;
      end;
      hence thesis by KURATO_0:4;
    end;
  end;
end;
