reserve A,B for Ordinal,
        o for object,
        x,y,z for Surreal,
        n for Nat,
        r,r1,r2 for Real;

theorem Th80:
  for r be Sequence of REAL
    for y,s be Sequence
       for alpha be Ordinal holds
    s|succ alpha,y,r simplest_on_position alpha iff
    s,y,r simplest_on_position alpha
proof
  let r be Sequence of REAL;
  let y,s be Sequence;
  let alpha be Ordinal;
  per cases;
  suppose dom s c= succ alpha;
    hence thesis by RELAT_1:68;
  end;
  suppose not dom s c= succ alpha;
    thus s|succ alpha,y,r simplest_on_position alpha implies
    s,y,r simplest_on_position alpha
    proof
      assume
A1:   s|succ alpha,y,r simplest_on_position alpha;
      let sa be Surreal such that
A2:   sa = s.alpha;
A3:   (s|succ alpha).alpha = sa by ORDINAL1:6,A2,FUNCT_1:49;
      hence 0 = alpha implies sa = 0_No by A1;
      assume
A4:   0 <> alpha;
      sa in_meets_terms s|succ alpha,y,r,alpha by A1,A3;
      hence sa in_meets_terms s,y,r,alpha by Th79;
      let x be uSurreal such that
A5:   x in_meets_terms s,y,r,alpha & x <> sa;
      x in_meets_terms s|succ alpha,y,r,alpha by A5,Th79;
      hence thesis by A4,A1,A3,A5;
    end;
    assume
A6: s,y,r simplest_on_position alpha;
    let sa be Surreal such that
A7: sa = (s|succ alpha).alpha;
A8: s.alpha = sa by ORDINAL1:6,A7,FUNCT_1:49;
    hence 0 = alpha implies sa = 0_No by A6;
    assume
A9: 0 <> alpha;
    sa in_meets_terms s,y,r,alpha by A6,A8;
    hence sa in_meets_terms s|succ alpha,y,r,alpha by Th79;
    let x be uSurreal such that
A10: x in_meets_terms s|succ alpha,y,r,alpha &
    x <> sa;
    x in_meets_terms s,y,r,alpha by A10,Th79;
    hence thesis by A9,A6,A8,A10;
  end;
end;
