reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem
  for V being ComplexLinearSpace, L being C_Linear_Combination of V, v
  being VECTOR of V st L is convex & ( ex r being Real st r = L.v & r <= 0 )
  holds not v in Carrier L
proof
  let V be ComplexLinearSpace;
  let L be C_Linear_Combination of V;
  let v be VECTOR of V;
  assume that
A1: L is convex and
A2: ex r being Real st r = L.v & r <= 0;
  consider r being Real such that
A3: r = L.v and
A4: r <= 0 by A2;
  per cases by A4;
  suppose
    r = 0;
    hence thesis by A3,Th1;
  end;
  suppose
A5: r < 0;
    now
      consider F being FinSequence of the carrier of V such that
      F is one-to-one and
A6:   rng F = Carrier L and
A7:   ex f being FinSequence of REAL st len f = len F & Sum(f) = 1 &
      for n being Nat st n in dom f holds f.n = L.(F.n) & f.n >= 0 by A1;
      assume v in Carrier L;
      then consider n be object such that
A8:   n in dom F and
A9:   F.n = v by A6,FUNCT_1:def 3;
      reconsider n as Element of NAT by A8;
      consider f being FinSequence of REAL such that
A10:  len f = len F and
      Sum f = 1 and
A11:  for n being Nat st n in dom f holds f.n =L.(F.n) & f.n >= 0 by A7;
      n in Seg len F by A8,FINSEQ_1:def 3;
      then
A12:  n in dom f by A10,FINSEQ_1:def 3;
      then L.v = f.n by A11,A9;
      hence contradiction by A3,A5,A11,A12;
    end;
    hence thesis;
  end;
end;
