
theorem
  for a, b being Ordinal
  st rng(omega -exponent CantorNF a) = rng(omega -exponent CantorNF b)
  for c being Ordinal st c in dom CantorNF a
  holds (omega -leading_coeff CantorNF (a(+)b)).c
    = (omega -leading_coeff CantorNF a).c + (omega -leading_coeff CantorNF b).c
proof
  let a, b be Ordinal;
  set E1 = omega -exponent CantorNF a, E2 = omega -exponent CantorNF b;
  set L1 = omega -leading_coeff CantorNF a;
  set L2 = omega -leading_coeff CantorNF b;
  assume A1: rng E1 = rng E2;
  then A2: E1 = E2 by Th34;
  consider C being Cantor-normal-form Ordinal-Sequence such that
    A3: a (+) b = Sum^ C & rng(omega -exponent C) = rng E1 \/ rng E2 and
    A4: for d being object st d in dom C holds
      (omega -exponent(C.d) in rng E1 \ rng E2 implies
        omega -leading_coeff(C.d) = L1.(E1".(omega -exponent(C.d)))) &
      (omega -exponent(C.d) in rng E2 \ rng E1 implies
        omega -leading_coeff(C.d) = L2.(E2".(omega -exponent(C.d)))) &
      (omega -exponent(C.d) in rng E1 /\ rng E2 implies
        omega -leading_coeff(C.d) = L1.(E1".(omega -exponent(C.d))) +
          L2.(E2".(omega -exponent(C.d)))) by Def5;
  let c be Ordinal;
  assume A5: c in dom CantorNF a;
  A6: dom CantorNF a = card dom E1 by Def1
    .= card rng E1 by CARD_1:70
    .= card dom(omega -exponent C) by A1, A3, CARD_1:70
    .= dom C by Def1;
  A7: rng(omega -exponent C) = rng E1 by A1, A3;
  then A8: rng(omega -exponent C) = rng E1 /\ rng E2 by A1;
  c in dom(omega -exponent C) by A5, A6, Def1;
  then (omega -exponent C).c in rng(omega -exponent C) by FUNCT_1:3;
  then A9: omega -exponent(C.c) in rng E1 /\ rng E2 by A5, A6, A8, Def1;
  A10: omega -exponent C = E1 by A7, Th34;
  A11: c in dom E1 by A5, Def1;
  thus (omega -leading_coeff CantorNF (a(+)b)).c
     = omega -leading_coeff(C.c) by A3, A5, A6, Def3
    .= L1.(E1".(omega -exponent(C.c))) + L2.(E2".(omega -exponent(C.c)))
      by A4, A5, A6, A9
    .= L1.(E1".(E1.c)) + L2.(E2".(omega -exponent(C.c))) by A5, A6, A10, Def1
    .= L1.(E1".(E1.c)) + L2.(E2".(E2.c)) by A2, A5, A6, A10, Def1
    .= L1.c + L2.(E2".(E2.c)) by A11, FUNCT_1:34
    .= L1.c + L2.c by A2, A11, FUNCT_1:34;
end;
