reserve m,n for Nat,
  a for Int_position,
  i,j for Instruction of SCMPDS,
  s,s1,s2 for State of SCMPDS,
  k1 for Integer,
  loc for Nat,
  I,J,K for Program of SCMPDS;
reserve P,P1,P2 for Instruction-Sequence of SCMPDS;

theorem Th72:
  for s being State of SCMPDS,I being Program of SCMPDS,a being
Int_position, k1 being Integer st s.DataLoc(s.a,k1) <= 0
 holds IExec(if>0(a,k1,I),P,Initialize s) = s +* Start-At((card I+1),SCMPDS)
proof
  let s be State of SCMPDS,I be Program of SCMPDS,a be Int_position, k1 be
  Integer;
  set b=DataLoc(s.a,k1);
  set IF=if>0(a,k1,I), pIF=stop IF, s3 = Initialize s,
  P3 = P +* pIF,
  s4 = Comput(P3, s3,1), P4 = P3;
  set i = (a,k1)<=0_goto (card I + 1);
  set SAl=Start-At((card I+1),SCMPDS);
A1: IC s3 = 0 by MEMSTR_0:47;
A2: not b in dom Start-At(0,SCMPDS) by SCMPDS_4:18;
  not a in dom Start-At(0,SCMPDS) by SCMPDS_4:18;
  then
A3: s3.DataLoc(s3.a,k1)=s3.b by FUNCT_4:11
    .= s.b by A2,FUNCT_4:11;
A4: Comput(P3, s3,0 + 1) = Following(P3,Comput(P3,s3,0)) by EXTPRO_1:3
    .= Following(P3,s3) by EXTPRO_1:2
    .= Exec(i,s3) by Th3;
  assume
  s.b <= 0;
  then
A5: IC s4 = ICplusConst(s3,card I + 1) by A4,A3,SCMPDS_2:56
    .= (0+(card I + 1)) by A1,Th4;
  pIF c= P3 by FUNCT_4:25;
  then
A6: pIF c= P4;
A7:  P3/.IC s4
 = P3.IC s4 by PBOOLE:143;
A8: card IF=card I+1 by Th1;
  then (card I+1) in dom pIF by COMPOS_1:64;
  then P4.(card I+1) = pIF.(card I+1) by A6,GRFUNC_1:2
    .=halt SCMPDS by A8,COMPOS_1:64;
  then
A9: CurInstr(P3,s4) = halt SCMPDS by A5,A7;
  then
A10: P3 halts_on s3 by EXTPRO_1:29;
A11: CurInstr(P3,s3) = i by Th3;
  now
    let l be Nat;
A12: Comput(P3,s3,0) = s3 by EXTPRO_1:2;
    assume
    l < 1;
    then l <1+0;
    then l=0 by NAT_1:13;
    then CurInstr(P3,Comput(P3,s3,l))
     = CurInstr(P3,s3) by A12;
    hence CurInstr(P3,Comput(P3,s3,l))
     <> halt SCMPDS by A11;
  end;
  then for l be Nat st CurInstr(P3,
  Comput(P3,s3,l)) = halt SCMPDS
  holds 1 <= l;
  then LifeSpan(P3,s3) = 1 by A9,A10,EXTPRO_1:def 15;
  then
A13: s4 = Result(P3,s3) by A10,EXTPRO_1:23;
A14: now
A15: dom SAl = {IC SCMPDS} by FUNCOP_1:13;
    let x be object;
    assume
A16: x in dom IExec(IF,P,Initialize s);
    per cases by A16,SCMPDS_4:6;
    suppose
A17:  x is Int_position;
      then x <> IC SCMPDS by SCMPDS_2:43;
      then
A18:  not x in dom SAl by A15,TARSKI:def 1;
A19:   not x in dom Start-At(0,SCMPDS) by A17,SCMPDS_4:18;
      thus IExec(IF,P,Initialize s).x = s4.x by A13
        .= s3.x by A4,A17,SCMPDS_2:56
        .= s.x by A19,FUNCT_4:11
        .= (s +* SAl).x by A18,FUNCT_4:11;
    end;
    suppose
A20:  x = IC SCMPDS;
      hence IExec(IF,P,Initialize s).x = (card I + 1) by A5,A13
        .= (s +* SAl).x by A20,FUNCT_4:113;
    end;
  end;
  dom IExec(IF,P,Initialize s) = the carrier of SCMPDS by PARTFUN1:def 2
    .= dom (s +* SAl) by PARTFUN1:def 2;
  hence thesis by A14,FUNCT_1:2;
end;
