
theorem asymTT5:
for a,b,p,q,r,s be Real, f be Function of REAL,REAL st
a > 0 & p > 0 &
for x be Real holds
f.x = max(r,min(s, ( (AffineMap (a,b)|].-infty,(q-b)/(a+p).[) +*
                     (AffineMap (-p,q)|[.(q-b)/(a+p),+infty.[) ) .x ))
holds f is Lipschitzian
proof
 let a,b,p,q,r,s be Real, f be Function of REAL,REAL;
 assume AP: a > 0 & p > 0;
 assume A2: for x be Real holds
  f.x = max(r,min(s, ( (AffineMap (a,b)|].-infty,(q-b)/(a+p).[) +*
                     (AffineMap (-p,q)|[.(q-b)/(a+p),+infty.[) ) .x ));
 set f1 = AffineMap (a,b)|].-infty,(q-b)/(a+p).[ +*
          AffineMap (-p,q)|[.(q-b)/(a+p),+infty.[;
 f1 is Function of REAL,REAL by asymTT10;then
 A4: dom f = REAL & dom f1 = REAL by FUNCT_2:def 1;
 ex r1 being Real st
 ( 0 < r1 &
 ( for x1, x2 being Real st x1 in dom f & x2 in dom f holds
  |.((f . x1) - (f . x2)).| <= r1 * |.(x1 - x2).| ) )
 proof
  consider r0 being Real such that
  A1: 0 < r0 and
  A3: for x1, x2 being Real st x1 in dom f1 & x2 in dom f1 holds
      |.f1.x1 - f1.x2.| <= r0 * |.x1 - x2.| by asymTT51,AP;
  take r0;
  for x1, x2 being Real st x1 in dom f & x2 in dom f holds
     |. f . x1 - f . x2 .| <= r0 * |. x1 - x2 .|
  proof
   let x1, x2 be Real;
   assume x1 in dom f & x2 in dom f; then
   A5: |.f1.x1 - f1.x2.| <= r0 * |.x1 - x2.| by A3,A4;
   |. f . x1 - f . x2 .|
    =|. max(r,min(s, f1 .x1 )) - f . x2 .| by A2
   .=|. max(r,min(s, f1.x1)) - max(r,min(s, f1.x2)) .| by A2; then
   |. f . x1 - f . x2 .| <= |. f1.x1 - f1.x2 .| by LeMM01;
   hence thesis by A5,XXREAL_0:2;
  end;
  hence thesis by A1;
 end;
 hence thesis;
end;
