reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th82:
  for G,H being strict GroupWithOperators of O st G,H
  are_isomorphic & G is simple holds H is simple
proof
  let G,H be strict GroupWithOperators of O;
  assume
A1: G,H are_isomorphic;
  assume
A2: G is simple;
  assume
A3: H is not simple;
  per cases by A3;
  suppose
    H is trivial;
    then G is trivial by A1,Th58;
    hence contradiction by A2;
  end;
  suppose
    ex H9 being strict normal StableSubgroup of H st H9 <> (Omega).H &
    H9 <> (1).H;
    then consider H9 be strict normal StableSubgroup of H such that
A4: H9 <> (Omega).H and
A5: H9 <> (1).H;
    consider f be Homomorphism of G,H such that
A6: f is bijective by A1;
    reconsider H99 = the multMagma of H9 as strict normal Subgroup of H by Lm6;
    the multMagma of H9 <> the multMagma of H by A4,Lm4;
    then consider h be Element of H such that
A7: not h in H99 by GROUP_2:62;
    the carrier of H9<>{1_H} by A5,Def8;
    then consider x be object such that
A8: x in the carrier of H9 and
A9: x<>1_H by ZFMISC_1:35;
A10: x in H99 by A8,STRUCT_0:def 5;
    then x in H by GROUP_2:40;
    then reconsider x as Element of H by STRUCT_0:def 5;
    consider y be Element of G such that
A11: f.y = x by A6,Th52;
    set A = {g where g is Element of G: f.g in H99};
    consider g be Element of G such that
A12: f.g = h by A6,Th52;
    1_H in H99 by GROUP_2:46;
    then f.(1_G) in H99 by Lm12;
    then 1_G in A;
    then reconsider A as non empty set;
    now
      let x be object;
      assume x in A;
      then ex g be Element of G st x=g & f.g in H99;
      hence x in the carrier of G;
    end;
    then reconsider A as Subset of G by TARSKI:def 3;
A13: now
      let g1,g2 be Element of G;
      assume that
A14:  g1 in A and
A15:  g2 in A;
      consider b be Element of G such that
A16:  b=g2 and
A17:  f.b in H99 by A15;
      consider a be Element of G such that
A18:  a=g1 and
A19:  f.a in H99 by A14;
      set fb = f.b;
      set fa = f.a;
      f.(a*b) = f.a * f.b & fa * fb in H99 by A19,A17,GROUP_2:50,GROUP_6:def 6;
      hence g1*g2 in A by A18,A16;
    end;
A20: now
      let o be Element of O;
      let g be Element of G;
      assume g in A;
      then consider a be Element of G such that
A21:  a=g and
A22:  f.a in H99;
      f.a in the carrier of H99 by A22,STRUCT_0:def 5;
      then f.a in H9 by STRUCT_0:def 5;
      then (H^o).(f.g) in H9 by A21,Lm9;
      then f.((G^o).g) in H9 by Def18;
      then f.((G^o).g) in the carrier of H9 by STRUCT_0:def 5;
      then f.((G^o).g) in H99 by STRUCT_0:def 5;
      hence (G^o).g in A;
    end;
    now
      let g be Element of G;
      assume g in A;
      then consider a be Element of G such that
A23:  a=g and
A24:  f.a in H99;
      (f.a)" in H99 by A24,GROUP_2:51;
      then f.(a") in H99 by Lm13;
      hence g" in A by A23;
    end;
    then consider G99 be strict StableSubgroup of G such that
A25: the carrier of G99 = A by A13,A20,Lm14;
    reconsider G9=the multMagma of G99 as strict Subgroup of G by Lm15;
    now
      let g be Element of G;
      now
        let x be object;
A26:    H99 |^ (f.g)" = H99 by GROUP_3:def 13;
        assume x in g * G9;
        then consider h be Element of G such that
A27:    x=g*h and
A28:    h in A by A25,GROUP_2:27;
        set h9=g*h*g";
A29:    f.h9 = f.(g*h) * f.(g") by GROUP_6:def 6
          .= f.g * f.h * f.(g") by GROUP_6:def 6
          .= ((f.g)")" * f.h * (f.g)" by Lm13
          .= f.h |^ (f.g)" by GROUP_3:def 2;
        ex a be Element of G st a=h & f.a in H99 by A28;
        then f.h9 in H99 by A26,A29,GROUP_3:58;
        then
A30:    h9 in A;
        h9*g = (g*h)*(g"*g) by GROUP_1:def 3
          .= (g*h)*1_G by GROUP_1:def 5
          .= x by A27,GROUP_1:def 4;
        hence x in G9 * g by A25,A30,GROUP_2:28;
      end;
      hence g * G9 c= G9 * g;
    end;
    then for H being strict Subgroup of G st H = the multMagma of G99 holds H
    is normal by GROUP_3:118;
    then
A31: G99 is normal;
A32: y<>1_G by A9,A11,Lm12;
    y in the carrier of G99 by A25,A10,A11;
    then the carrier of G99 <> {1_G} by A32,TARSKI:def 1;
    then
A33: G99<>(1).G by Def8;
    now
      assume g in A;
      then ex g9 be Element of G st g9=g & f.g9 in H99;
      hence contradiction by A7,A12;
    end;
    then G99<>(Omega).G by A25;
    hence contradiction by A2,A33,A31;
  end;
end;
