
theorem Th82:
  for X be non empty set, S be SigmaField of X, M be sigma_Measure
of S, f be PartFunc of X,ExtREAL, A be Element of S st (ex E be Element of S st
E = dom f & f is E-measurable ) & f is nonnegative & M.A = 0 holds integral+
  (M,f|A) = 0
proof
  let X be non empty set, S be SigmaField of X, M be sigma_Measure of S, f be
  PartFunc of X,ExtREAL, A be Element of S;
  assume that
A1: ex E be Element of S st E = dom f & f is E-measurable and
A2: f is nonnegative and
A3: M.A = 0;
  consider F0 be Functional_Sequence of X,ExtREAL, K0 be ExtREAL_sequence such
  that
A4: for n be Nat holds F0.n is_simple_func_in S & dom(F0.n) = dom f and
A5: for n be Nat holds F0.n is nonnegative and
A6: for n,m be Nat st n <=m holds for x be Element of X st x in dom f
  holds (F0.n).x <= (F0.m).x and
A7: for x be Element of X st x in dom f holds F0#x is convergent & lim(
  F0#x) = f.x and
  for n be Nat holds K0.n=integral'(M,F0.n) and
  K0 is convergent and
  integral+(M,f)=lim K0 by A1,A2,Def15;
  deffunc PFA(Nat) = (F0.$1)|A;
  consider FA be Functional_Sequence of X,ExtREAL such that
A8: for n be Nat holds FA.n=PFA(n) from SEQFUNC:sch 1;
  consider E be Element of S such that
A9: E = dom f and
A10: f is E-measurable by A1;
  set C = E/\A;
A11: f|A is nonnegative by A2,Th15;
A12: dom f /\ C = C by A9,XBOOLE_1:17,28;
  then
A13: dom(f|C) = C by RELAT_1:61;
  then
A14: dom(f|C) = dom(f|A) by A9,RELAT_1:61;
  for x be object st x in dom(f|A) holds f|A.x = f|C.x
  proof
    let x be object;
    assume
A15: x in dom(f|A);
    then (f|A).x = f.x by FUNCT_1:47;
    hence thesis by A14,A15,FUNCT_1:47;
  end;
  then
A16: f|A = f|C by A9,A13,FUNCT_1:2,RELAT_1:61;
  f is C-measurable by A10,MESFUNC1:30,XBOOLE_1:17;
  then
A17: f|A is C-measurable by A12,A16,Th42;
A18: for n be Nat holds FA.n is nonnegative
  proof
    let n be Nat;
    reconsider n as Element of NAT by ORDINAL1:def 12;
    F0.n|A is nonnegative by A5,Th15;
    hence thesis by A8;
  end;
  deffunc PK(Nat) = integral'(M,FA.$1);
  consider KA be ExtREAL_sequence such that
A19: for n be Element of NAT holds KA.n = PK(n) from FUNCT_2:sch 4;
A20: now
    let n be Nat;
    n in NAT by ORDINAL1:def 12;
    hence KA.n = PK(n) by A19;
  end;
A21: for n be Nat holds KA.n =0
  proof
    let n be Nat;
    reconsider n as Element of NAT by ORDINAL1:def 12;
    F0.n is_simple_func_in S by A4;
    then integral'(M,F0.n|A) = 0 by A3,A5,Th73;
    then integral'(M,FA.n) = 0 by A8;
    hence thesis by A20;
  end;
  then
A22: lim KA = 0 by Th60;
A23: C = dom(f|A) by A9,RELAT_1:61;
A24: for n be Nat holds FA.n is_simple_func_in S & dom(FA.n) = dom(f|A)
  proof
    let n be Nat;
    reconsider n1=n as Element of NAT by ORDINAL1:def 12;
    FA.n1=F0.n1|A by A8;
    hence FA.n is_simple_func_in S by A4,Th34;
    dom(FA.n1)=dom(F0.n1|A) by A8;
    then dom(FA.n)=dom(F0.n) /\ A by RELAT_1:61;
    hence thesis by A9,A4,A23;
  end;
A25: for x be Element of X st x in dom(f|A) holds FA#x is convergent & lim(
  FA#x) = f|A.x
  proof
    let x be Element of X;
    assume
A26: x in dom(f|A);
    now
      let n be Element of NAT;
A27:  dom(F0.n|A) = dom(FA.n) by A8
        .=dom(f|A) by A24;
      thus (FA#x).n = (FA.n).x by Def13
        .=(F0.n|A).x by A8
        .=(F0.n).x by A26,A27,FUNCT_1:47
        .=(F0#x).n by Def13;
    end;
    then
A28: FA#x = F0#x by FUNCT_2:63;
    x in dom f /\ A by A26,RELAT_1:61;
    then
A29: x in dom f by XBOOLE_0:def 4;
    then lim(F0#x)=f.x by A7;
    hence thesis by A7,A26,A29,A28,FUNCT_1:47;
  end;
A30: for n,m be Nat st n <=m holds for x be Element of X st x in dom(f|A)
  holds (FA.n).x <= (FA.m).x
  proof
    let n,m be Nat;
    assume
A31: n<=m;
    let x be Element of X;
    reconsider n,m as Element of NAT by ORDINAL1:def 12;
    assume
A32: x in dom(f|A);
    then x in dom f /\ A by RELAT_1:61;
    then
A33: x in dom f by XBOOLE_0:def 4;
    dom(F0.m|A) = dom(FA.m) by A8;
    then
A34: dom(F0.m|A) = dom(f|A) by A24;
    (FA.m).x =(F0.m|A).x by A8;
    then
A35: (FA.m).x = (F0.m).x by A32,A34,FUNCT_1:47;
    dom(F0.n|A) = dom(FA.n) by A8;
    then
A36: dom(F0.n|A) = dom(f|A) by A24;
    (FA.n).x =(F0.n|A).x by A8;
    then (FA.n).x = (F0.n).x by A32,A36,FUNCT_1:47;
    hence thesis by A6,A31,A33,A35;
  end;
  KA is convergent by A21,Th60;
  hence thesis by A17,A20,A23,A11,A24,A18,A30,A25,A22,Def15;
end;
