reserve A,B for Ordinal,
        o for object,
        x,y,z for Surreal,
        n for Nat,
        r,r1,r2 for Real;

theorem Th82:
  for r be non-zero Sequence of REAL
    for y be strictly_decreasing Surreal-Sequence
      ex s be uSurreal-Sequence st
        dom s = succ (dom r/\dom y) & s,y,r simplest_up_to dom s
proof
  let r be non-zero Sequence of REAL;
  let y be strictly_decreasing Surreal-Sequence;
  defpred P[Ordinal] means $1 c= dom r/\dom y implies
    ex s be uSurreal-Sequence st
      dom s = succ $1 & s,y,r simplest_up_to dom s;
A1: for D be Ordinal st for C be Ordinal st C in D holds P[C] holds P[D]
  proof
    let D be Ordinal such that
A2: for C be Ordinal st C in D holds P[C];
    assume
A3: D c= dom r/\dom y;
    then
A4: D c= dom y & D c= dom r by XBOOLE_1:18;
    A5 :D c= dom y & D c= dom r by A3,XBOOLE_1:18;
    per cases;
    suppose
A6:   D={};
      take s = <%0_No%>;
      thus
A7:   dom s = succ D by A6,AFINSQ_1:def 4;
      let A be Ordinal such that
A8:   A in dom s;
      let sa be Surreal;
      assume sa = s.A;
      hence thesis by A8,A6,A7,ORDINAL1:8;
    end;
    suppose
A9:   D is limit_ordinal & D<>{};
      defpred U[object,object] means for A be Ordinal st A=$1
      holds $2 is uSurreal-Sequence &
      for s be uSurreal-Sequence st s=$2 holds
      dom s = succ A & s,y,r simplest_up_to dom s;
A10:  for e being object st e in D ex o st U[e,o]
      proof
        let e be object such that
A11:    e in D;
        reconsider E=e as Ordinal by A11;
        consider s be uSurreal-Sequence such that
A12:    dom s = succ E &
        s,y,r simplest_up_to dom s by A11,ORDINAL1:def 2,A3,A2;
        take s;
        thus thesis by A12;
      end;
      consider S be Function such that
A13:  dom S = D &
      for o st o in D holds U[o,S.o] from CLASSES1:sch 1(A10);
      o in rng S implies o is Function
      proof
        assume o in rng S;
        then ex a be object st a in dom S & S.a =o by FUNCT_1:def 3;
        hence thesis by A13;
      end;
      then S is Function-yielding by FUNCT_1:def 13;
      then reconsider S as Function-yielding Function;
      deffunc S(Ordinal) = S.$1.$1;
      consider s be Sequence such that
A14:  dom s = D &
      for A be Ordinal st A in D holds s.A = S(A) from ORDINAL2:sch 2;
      rng s is uniq-surreal-membered
      proof
        let a be object such that
A15:    a in rng s;
        consider x be object such that
A16:    x in dom s & s.x =a by A15,FUNCT_1:def 3;
        reconsider x as Ordinal by A16;
        reconsider Sx =S.x as uSurreal-Sequence by A16,A13,A14;
        x in succ x = dom Sx by A16,A14,A13,ORDINAL1:6;
        then Sx.x in rng Sx by FUNCT_1:def 3;
        then Sx.x is uSurreal by SURREALO:def 12;
        hence thesis by A14,A16;
      end;
      then reconsider s as uSurreal-Sequence by Def10;
      defpred S[Ordinal] means $1 in D implies S.$1 = s|succ $1 &
      s,y,r simplest_on_position $1;
A17:  for E be Ordinal holds S[E]
      proof
        let E be Ordinal;
        assume
A18:    E in D;
        reconsider SE =S.E as uSurreal-Sequence by A18,A13;
A19:    succ E c= D by ORDINAL1:def 2,A18,A9,ORDINAL1:28;
A20:    dom SE = succ E &
        SE,y,r simplest_up_to dom SE by A18,A13;
A21:    dom (s|succ E) = succ E by A19,RELAT_1:62,A14;
        o in succ E implies (s|succ E).o = SE.o
        proof
          assume
A22:      o in succ E;
          then reconsider o as Ordinal;
A23:      (s|succ E).o = s.o by A22,FUNCT_1:49;
          per cases by A22,ORDINAL1:8;
          suppose
A24:        o in E;
A25:        o in D by A18,A24,ORDINAL1:10;
            reconsider So =S.o as uSurreal-Sequence by A25,A13;
A26:        So.o = s.o by A14,A18,A24,ORDINAL1:10;
A27:        dom So = succ o & So,y,r simplest_up_to dom So by A25,A13;
A28:        dom So c= dom SE by A27,A20,A22,ORDINAL1:21;
A29:        SE,y,r simplest_up_to dom So by A28,A20;
            (So|succ o).o = So.o & (SE|succ o).o = SE.o
            by ORDINAL1:6,FUNCT_1:49;
            hence thesis by A26,A23,A27,A29,A28,Th77;
          end;
          suppose o = E;
            hence thesis by A23,A14,A18;
          end;
        end;
        then
A30:    s|succ E = SE by A20,A21,FUNCT_1:2;
        E in succ E by ORDINAL1:6;
        hence thesis by A20,A30,Th80;
      end;
      then
A31:  s,y,r simplest_up_to D;
      defpred upper[object,object] means $2 is Surreal &
      for A be Ordinal st A= $1
      for sa,ya be Surreal st sa = s.succ A & ya = y.succ A holds
      $2 = sa + uReal.(r.succ A)* No_omega^ ya +No_omega^ ya;
A32:  for e being object st e in D ex o st upper[e,o]
      proof
        let e be object such that
A33:    e in D;
        reconsider E=e as Ordinal by A33;
        succ E in D by A33,A9,ORDINAL1:28;
        then y.(succ E) in rng y & s.(succ E) in rng s
        by A4,A14,FUNCT_1:def 3;
        then reconsider ya = y.(succ E),sa=s.(succ E) as Surreal
        by SURREAL0:def 16;
        take o = sa + uReal.(r.succ E)* No_omega^ ya +No_omega^ ya;
        thus thesis;
      end;
      consider upp be Function such that
A34:  dom upp = D and
A35:  for o st o in D holds upper[o,upp.o] from CLASSES1:sch 1(A32);
A36:  rng upp is surreal-membered
      proof
        let o such that
A37:    o in rng upp;
        ex a be object st a in dom upp & upp.a = o by A37,FUNCT_1:def 3;
        hence thesis by A34,A35;
      end;
A38:  for A,B be Ordinal st A in B in D
      for uA,uB be Surreal st uA =upp.A & uB =upp.B
      holds uB < uA
      proof
        let A,B be Ordinal such that
A39:    A in B in D;
        let uA,uB be Surreal such that
A40:    uA =upp.A & uB =upp.B;
        succ B in D by A39,A9,ORDINAL1:28;
        then y.(succ B) in rng y & s.(succ B) in rng s
        by A4,A14,FUNCT_1:def 3;
        then reconsider yB = y.(succ B),sB=s.(succ B) as Surreal
        by SURREAL0:def 16;
A41:    A in D by A39,ORDINAL1:10;
        then succ A in D by A9,ORDINAL1:28;
        then y.(succ A) in rng y & s.(succ A) in rng s
        by A4,A14,FUNCT_1:def 3;
        then reconsider yA = y.(succ A),sA=s.(succ A) as Surreal
        by SURREAL0:def 16;
        set NA = No_omega^ yA,NB = No_omega^ yB;
A42:    succ B in D by A39,A9,ORDINAL1:28;
        s,y,r simplest_on_position succ B by A31,A39,A9,ORDINAL1:28;
        then
A43:    sB in_meets_terms s,y,r,succ B;
        set n = 2;
A44:    uA = sA + uReal.(r.succ A)* NA +NA &
        uB = sB + uReal.(r.succ B)* NB +NB by A40,A41,A39,A35;
A45:    succ A c= B by A39,ORDINAL1:21;
        then sB  is (sA,yA,r.succ A)_term by A43,ORDINAL1:22;
        then |.sB - (sA + uReal.(r.succ A)*NA) .| infinitely< NA by Th73;
        then |.sB +- (sA + uReal.(r.succ A)*NA) .| infinitely< NA * uReal.(1/n)
        by Th13;
        then |.sB +- (sA + uReal.(r.succ A)*NA) .| < NA * uReal.(1/n) by Th9;
        then sB - (sA + uReal.(r.succ A)*NA) < NA * uReal.(1/n) by Th52;
        then
A46:    sB < NA * uReal.(1/n) + (sA + uReal.(r.succ A)*NA)
        by SURREALR:41;
        uReal.(r.succ B)* NB +NB = uReal.(r.succ B)* NB + uReal.1 * NB
        by SURREALN:48;
        then
A47:    uReal.(r.succ B)* NB +NB == (uReal.(r.succ B) + uReal.1) * NB
        by SURREALR:67;
        (uReal.(r.succ B) + uReal.1) * NB == uReal.(1+r.succ B) * NB
        by SURREALR:51,SURREALN:55;
        then
A48:    uReal.(r.succ B)* NB +NB == uReal.(1+r.succ B) * NB
        by A47,SURREALO:4;
        yB < yA by Def11,A5,A45,ORDINAL1:22,A42;
        then NB infinitely< NA by Lm5;
        then 0_No <=NB infinitely< NA * uReal.(1/n) by Th13,SURREALI:def 8;
        then uReal.(1+r.succ B) * NB < NA * uReal.(1/n) by Th20;
        then
A49:    uReal.(r.succ B)* NB +NB < NA * uReal.(1/n)
        by A48,SURREALO:4;
        uB = sB + (uReal.(r.succ B)* NB +NB) by A44,SURREALR:37;
        then
A50:    uB <= sB + NA * uReal.(1/n) by A49,SURREALR:44;
        sB + NA * uReal.(1/n) < NA * uReal.(1/n) + (sA + uReal.(r.succ A)*NA)
        + NA * uReal.(1/n) by A46,SURREALR:44;
        then
A51:    uB < NA * uReal.(1/n) + (sA + uReal.(r.succ A)*NA)
        + NA * uReal.(1/n) by A50,SURREALO:4;
        1/n+1/n = 1;
        then
A52:    NA*(uReal.(1/n) + uReal.(1/n)) == NA *1_No =NA
        by SURREALR:51,SURREALN:55,SURREALN:48;
        NA*(uReal.(1/n) + uReal.(1/n)) == NA*uReal.(1/n) + NA*uReal.(1/n)
        by SURREALR:67;
        then
A53:    NA == NA*uReal.(1/n) + NA*uReal.(1/n) by A52,SURREALO:4;
        NA * uReal.(1/n) + (sA + uReal.(r.succ A)*NA) + NA * uReal.(1/n)
        = (NA * uReal.(1/n) + NA * uReal.(1/n)) + (sA + uReal.(r.succ A)*NA)
        == NA +(sA + uReal.(r.succ A)*NA) by SURREALR:37,A53,SURREALR:43;
        hence thesis by A44,A51,SURREALO:4;
      end;
      defpred lower[object,object] means $2 is Surreal &
      for A be Ordinal st A= $1
        for sa,ya be Surreal st sa = s.succ A & ya = y.succ A holds
          $2 = sa + uReal.(r.succ A)* No_omega^ ya + -No_omega^ ya;
A54:  for e being object st e in D ex o st lower[e,o]
      proof
        let e be object such that
A55:    e in D;
        reconsider E=e as Ordinal by A55;
        succ E in D by A55,A9,ORDINAL1:28;
        then y.(succ E) in rng y & s.(succ E) in rng s by A4,A14,FUNCT_1:def 3;
        then reconsider ya = y.(succ E),sa=s.(succ E) as Surreal
        by SURREAL0:def 16;
        take o = sa + uReal.(r.succ E)* No_omega^ ya +- No_omega^ ya;
        thus thesis;
      end;
      consider low be Function such that
A56:  dom low = D and
A57:  for o st o in D holds lower[o,low.o] from CLASSES1:sch 1(A54);
A58:  rng low is surreal-membered
      proof
        let o such that
A59:    o in rng low;
        ex a be object st a in dom low & low.a = o by A59,FUNCT_1:def 3;
        hence thesis by A56,A57;
      end;
A60:  for A,B be Ordinal st A in B in D
      for lA,lB be Surreal st lA =low.A & lB =low.B holds lA < lB
      proof
        let A,B be Ordinal such that
A61:    A in B in D;
        let uA,uB be Surreal such that
A62:    uA =low.A & uB =low.B;
A63:    succ B in D c= dom y by A3,XBOOLE_1:18,A61,A9,ORDINAL1:28;
        y.(succ B) in rng y & s.(succ B) in rng s
        by A63,A14,FUNCT_1:def 3;
        then reconsider yB = y.(succ B),sB=s.(succ B) as Surreal
        by SURREAL0:def 16;
A64:    A in D by A61,ORDINAL1:10;
        then succ A in D by A9,ORDINAL1:28;
        then y.(succ A) in rng y & s.(succ A) in rng s
        by A4,A14,FUNCT_1:def 3;
        then reconsider yA = y.(succ A),sA=s.(succ A) as Surreal
        by SURREAL0:def 16;
        set NA = No_omega^ yA,NB = No_omega^ yB;
A65:    succ B in D by A61,A9,ORDINAL1:28;
        s,y,r simplest_on_position succ B by A31,A61,A9,ORDINAL1:28;
        then
A66:    sB in_meets_terms s,y,r,succ B;
        set n = 2;
A67:    uA = sA + uReal.(r.succ A)* NA +- NA &
        uB = sB + uReal.(r.succ B)* NB +- NB by A62,A64,A61,A57;
A68:    succ A c= B by A61,ORDINAL1:21;
        then sB  is (sA,yA,r.succ A)_term by A66,ORDINAL1:22;
        then |.sB - (sA + uReal.(r.succ A)*NA) .| infinitely< NA by Th73;
        then |.sB +- (sA + uReal.(r.succ A)*NA) .| infinitely<
          NA * uReal.(1/n) by Th13;
        then |.sB +- (sA + uReal.(r.succ A)*NA) .| < NA * uReal.(1/n)
        by Th9;
        then -(NA * uReal.(1/n)) < sB - (sA + uReal.(r.succ A)*NA) by Th52;
        then
A69:    -( NA * uReal.(1/n)) + (sA + uReal.(r.succ A)*NA) < sB by SURREALR:42;
        - uReal.(r.succ B)* NB + NB = (- uReal.(r.succ B))* NB + (uReal.1) * NB
        by SURREALR:58,SURREALN:48;
        then
A70:    -uReal.(r.succ B)* NB + NB == (-uReal.(r.succ B) + uReal.1) * NB
        by SURREALR:67;
        - uReal.(r.succ B) == uReal.-(r.succ B) by SURREALN:56;
        then
A71:    -uReal.(r.succ B) + uReal.1 == uReal.(-r.succ B) + uReal.1
        by SURREALR:43;
        uReal.(-r.succ B) + uReal.1 == uReal.(1+-r.succ B) by SURREALN:55;
        then - uReal.(r.succ B) + uReal.1 == uReal.(1+-r.succ B)
        by A71,SURREALO:4;
        then (-uReal.(r.succ B) + uReal.1) * NB == uReal.(1+-r.succ B) * NB
        by SURREALR:51;
        then
A72:    -uReal.(r.succ B)* NB + NB == uReal.(1+-r.succ B) * NB
        by A70,SURREALO:4;
        yB < yA by A4,Def11, A68,ORDINAL1:22,A65;
        then NB infinitely< NA by Lm5;
        then 0_No <=NB infinitely< NA * uReal.(1/n) by Th13,SURREALI:def 8;
        then uReal.(1+-r.succ B) * NB < NA * uReal.(1/n) by Th20;
        then -uReal.(r.succ B)* NB + NB < NA * uReal.(1/n) by A72,SURREALO:4;
        then
A73:    - NA * uReal.(1/n) < -(-uReal.(r.succ B)* NB + NB)
        = - -uReal.(r.succ B)* NB + -NB by SURREALR:10,40;
        sB + (uReal.(r.succ B)* NB +- NB) = uB by A67,SURREALR:37;
        then
A74:    sB + - (NA * uReal.(1/n)) < uB by A73,SURREALR:44;
        - (NA * uReal.(1/n)) + (sA + uReal.(r.succ A)*NA)
        +- (NA * uReal.(1/n)) <= sB + - (NA * uReal.(1/n))
        by A69,SURREALR:44;
        then
A75:    - (NA * uReal.(1/n)) + (sA + uReal.(r.succ A)*NA)
        +- (NA * uReal.(1/n)) < uB by A74,SURREALO:4;
        1/n+1/n = 1;
        then
A76:    NA*(uReal.(1/n) + uReal.(1/n)) == NA *1_No =NA
        by SURREALN:55,48,SURREALR:51;
        NA*(uReal.(1/n) + uReal.(1/n)) == NA*uReal.(1/n) + NA*uReal.(1/n)
        by SURREALR:67;
        then NA == NA*uReal.(1/n) + NA*uReal.(1/n) by A76,SURREALO:4;
        then - NA == -(NA*uReal.(1/n) + NA*uReal.(1/n)) by SURREALR:10;
        then
A77:    -NA == -(NA*uReal.(1/n)) +-( NA*uReal.(1/n)) by SURREALR:40;
        - NA * uReal.(1/n) + (sA + uReal.(r.succ A)*NA) + - NA * uReal.(1/n)
        = (-NA * uReal.(1/n) + - NA * uReal.(1/n)) + (sA + uReal.(r.succ A)*NA)
        == - NA +(sA + uReal.(r.succ A)*NA)
        by SURREALR:37,A77,SURREALR:43;
        hence thesis by A75,A67,SURREALO:4;
      end;
A78:  for A be Ordinal st A in D
      for lA,uA be Surreal st lA =low.A & uA =upp.A holds lA < uA
      proof
        let A be Ordinal such that
A79:    A in D;
        let lA,uA be Surreal such that
A80:    lA =low.A & uA =upp.A;
        succ A in D by A79,A9,ORDINAL1:28;
        then y.(succ A) in rng y & s.(succ A) in rng s
        by A4,A14,FUNCT_1:def 3;
        then reconsider yA = y.(succ A),sA=s.(succ A) as Surreal
        by SURREAL0:def 16;
        set NA = No_omega^ yA;
A81:    lA = sA + uReal.(r.succ A)* NA +- NA &
        uA = sA + uReal.(r.succ A)* NA + NA by A79,A80,A57,A35;
        -NA <= -0_No = 0_No by SURREALI:def 8,SURREALR:10;
        then -NA < NA by SURREALI:def 8,SURREALO:4;
        hence thesis by A81,SURREALR:44;
      end;
A82:  rng low << rng upp
      proof
        let l,u be Surreal such that
A83:    l in rng low & u in rng upp;
        consider A be object such that
A84:    A in dom low & low.A = l by A83,FUNCT_1:def 3;
        consider B be object such that
A85:    B in dom upp & upp.B = u by A83,FUNCT_1:def 3;
        reconsider A,B as Ordinal by A84,A85,A56,A34;
        reconsider lowB =low.B,uppA=upp.A as Surreal
        by A84,A85,A56,A57,A34,A35;
        per cases by ORDINAL1:14;
        suppose A=B;
          hence thesis by A84,A85,A78,A56;
        end;
        suppose A in B;
          then l < lowB <= u by A60,A84,A85,A34,A78;
          hence thesis by SURREALO:4;
        end;
        suppose B in A;
          then l <= uppA < u by A38,A84,A85,A56,A78;
          hence thesis by SURREALO:4;
        end;
      end;
      consider M be Ordinal such that
A86:  for o st o in rng low \/ rng upp
      ex A be Ordinal st A in M & o in Day A by A36,A58,SURREAL0:47;
      [rng low,rng upp] in Day M by A82,A86,SURREAL0:46;
      then reconsider rLU =[rng low,rng upp] as Surreal;
      defpred Simpl[Surreal] means $1 in_meets_terms s,y,r,D;
      rLU in_meets_terms s,y,r,D
      proof
        let A be Ordinal,sb,yb be Surreal such that
A87:    A in D & sb=s.A & yb = y.A;
        reconsider lowA =low.A,uppA=upp.A as Surreal by A87,A57,A35;
A88:    succ A in D by A87,A9,ORDINAL1:28;
        then y.(succ A) in rng y & s.(succ A) in rng s
        by A4,A14,FUNCT_1:def 3;
        then reconsider yA = y.(succ A),sA=s.(succ A) as Surreal
        by SURREAL0:def 16;
        set NA = No_omega^ yA;
A89:    lowA = sA + uReal.(r.succ A)* NA +- NA &
        uppA = sA + uReal.(r.succ A)* NA + NA by A87,A57,A35;
A90:    r.A in rng r by A87,A4,FUNCT_1:def 3;
        s,y,r simplest_on_position succ A by A31,A87,A9,ORDINAL1:28;
        then
A91:    sA in_meets_terms s,y,r,succ A;
        sA is (sb,yb,r.A)_term by ORDINAL1:6,A87,A91;
        then
A92:    |. sA - (sb + uReal.(r.A)* No_omega^ yb).| infinitely<
        No_omega^yb by Th73;
        yA < yb by ORDINAL1:6,A88,A87,Def11,A5;
        then
A93:    NA infinitely< No_omega^ yb by Lm5;
A94:    lowA in rng low & uppA in rng upp by A87,A56,A34,FUNCT_1:def 3;
A95:    L_rLU << {rLU} << R_rLU & rLU in {rLU}
        by SURREALO:11,TARSKI:def 1;
        then - rLU < -(sA + uReal.(r.succ A)* NA +- NA) by A94,A89,SURREALR:10;
        then
A96:    - rLU + (sb + uReal.(r.A)* No_omega^ yb)
        <= -(sA + uReal.(r.succ A)* NA +- NA)+(sb + uReal.(r.A)* No_omega^ yb)
        by SURREALR:44;
A97:    - rLU + (sb + uReal.(r.A)* No_omega^ yb) =
        - rLU + - - (sb + uReal.(r.A)* No_omega^ yb)
        .= - (rLU + - (sb + uReal.(r.A)* No_omega^ yb)) by SURREALR:40;
A98:    -(sA + uReal.(r.succ A)* NA +- NA)+
        (sb + uReal.(r.A)* No_omega^ yb)
        =(-(sA + uReal.(r.succ A)* NA) +- -NA)+(sb+ uReal.(r.A)* No_omega^ yb)
        by SURREALR:40
        .= ((-sA+-(uReal.(r.succ A)* NA) + NA))+(sb+uReal.(r.A)* No_omega^ yb)
        by SURREALR:40
        .= -sA+(-(uReal.(r.succ A)* NA)+NA)+(sb+uReal.(r.A)* No_omega^ yb)
        by SURREALR:37
        .= -sA +- - (sb + uReal.(r.A)* No_omega^ yb)
        + (- (uReal.(r.succ A)* NA) + NA) by SURREALR:37
        .= -(sA +- (sb + uReal.(r.A)* No_omega^ yb)) +
        (- (uReal.(r.succ A)* NA) + NA) by SURREALR:40;
A99:   0_No <= NA by SURREALI:def 8;
        then
A100:   NA = |.NA.| by Def6;
A101:   |.uReal.(r.succ A)* NA.| infinitely< No_omega^ yb
        by A93,A99,Th53;
        then |. (NA+ uReal.(r.succ A)* NA).| infinitely< No_omega^ yb
        by A93,Th41,A100;
        then
A102:   |.(sA +- (sb + uReal.(r.A)* No_omega^ yb))
        + (NA+ uReal.(r.succ A)* NA).|
        infinitely< No_omega^ yb by A92,Th41;
A103:   |.-(sA +- (sb + uReal.(r.A)* No_omega^ yb)).| infinitely<
        No_omega^yb by A92,Th42;
        |. (NA- uReal.(r.succ A)* NA).| infinitely< No_omega^ yb
        by A93,Th43,A100,A101;
        then
A104:   |.-(sA +- (sb + uReal.(r.A)* No_omega^ yb))
        + (NA+- uReal.(r.succ A)* NA) .| infinitely< No_omega^yb by A103,Th41;
        -(sA +- (sb + uReal.(r.A)* No_omega^ yb))
        + (NA+- uReal.(r.succ A)* NA) infinitely< No_omega^yb
        by Th34,Th11,A104;
        then
A105:   - (rLU + - (sb + uReal.(r.A)* No_omega^ yb))
        infinitely< No_omega^yb by A97,A96,A98,Th11;
A106:   rLU +- (sb + uReal.(r.A)* No_omega^ yb) <=
        sA + uReal.(r.succ A)* NA + NA +- (sb + uReal.(r.A)* No_omega^ yb)
        by A94,A95,A89,SURREALR:44;
A107:   sA + uReal.(r.succ A)* NA + NA +-
        (sb + uReal.(r.A)* No_omega^ yb)=
        sA + (uReal.(r.succ A)* NA + NA) +- (sb + uReal.(r.A)* No_omega^ yb)
        by SURREALR:37
        .= sA +- (sb + uReal.(r.A)* No_omega^ yb) + (NA+ uReal.(r.succ A)* NA)
        by SURREALR:37;
        (sA +- (sb + uReal.(r.A)* No_omega^ yb)) + (NA+ uReal.(r.succ A)* NA)
        infinitely< No_omega^ yb by Th34,A102,Th11;
        then rLU +- (sb + uReal.(r.A)* No_omega^ yb) infinitely< No_omega^ yb
        by A107,A106,Th11;
        then |. rLU-(sb+uReal.(r.A)* No_omega^ yb).| infinitely< No_omega^yb
        by Def6,A105;
        hence rLU is (sb,yb,r.A)_term by A90,Th73;
      end;
      then
A108: ex x be Surreal st Simpl[x];
A109: for x,y,z be Surreal st x <= y <= z & Simpl[x] & Simpl[z]
      holds Simpl[y] by Th81,A3,XBOOLE_1:18;
      consider sD be uSurreal such that
A110: Simpl[sD] and
A111: for x be uSurreal st Simpl[x] & x <> sD holds born sD in born x
      from Simplest(A108,A109);
      take ssD=s^<%sD%>;
A112: dom <%sD%> = 1 by AFINSQ_1:def 4;
      then dom ssD = (dom s)+^ 1 by ORDINAL4:def 1;
      hence
A113: dom ssD = succ D by A14,ORDINAL2:31;
      let B be Ordinal such that
A114: B in dom ssD;
A115: dom s = dom ssD/\dom s by ORDINAL7:1,A14,A113;
      for o be object st o in dom s holds s.o = ssD.o by ORDINAL4:def 1;
      then
A116: ssD|D = s by A115,FUNCT_1:46,A14;
A117: s|D = s by A14;
      per cases by A113,A114,ORDINAL1:8;
      suppose
A118:   B = D;
        ssD,y,r simplest_on_position D
        proof
          let sa be Surreal such that
A119:     sa = ssD.D;
          0 in dom <%sD%> by A112,TARSKI:def 1,CARD_1:49;
          then ssD.(D+^0) = <%sD%>.0 = sD by A14,ORDINAL4:def 1;
          then
A120:     sa = sD by A119,ORDINAL2:27;
          thus 0 = D implies sa = 0_No by A9;
          assume 0<>D;
          thus sa in_meets_terms ssD,y,r,D by A110,A116,A117,Th75,A120;
          let x be uSurreal;
          thus thesis by A116,A117,Th75,A111,A120;
        end;
        hence thesis by A118;
      end;
      suppose
A121:   B in D;
        then
A122:   s|succ B,y,r simplest_on_position B by A17,Th80;
        ssD|succ B = s|succ B by A121,ORDINAL1:21,A116,RELAT_1:74;
        hence thesis by A122,Th80;
      end;
    end;
    suppose not D is limit_ordinal;
      then consider d be Ordinal such that
A123: D = succ d by ORDINAL1:29;
A124: d in D by A123,ORDINAL1:6;
      consider s be uSurreal-Sequence such that
A125: dom s = succ d and
A126: s,y,r simplest_up_to dom s by ORDINAL1:def 2,A124,A2,A3;
      d in dom r & d in dom y by A124,XBOOLE_0:def 4,A3;
      then
A127: r.d in rng r & y.d in rng y by FUNCT_1:def 3;
      then reconsider yd = y.d as Surreal by SURREAL0:def 16;
      s.d in rng s by A125,A123,A124,FUNCT_1:def 3;
      then reconsider sd=s.d as uSurreal by SURREALO:def 12;
      set c = sd + uReal.(r.d)* No_omega^ yd;
      s,y,r simplest_on_position d by A126,ORDINAL1:6,A125;
      then
A128: (0 = d implies sd = 0_No) &
      (0 <> d implies sd in_meets_terms s,y,r,d &
      for x be uSurreal st x in_meets_terms s,y,r,d & x <> sd
      holds born sd in born x);
      defpred Simpl[Surreal] means $1 in_meets_terms s,y,r,D;
      c in_meets_terms s,y,r,D
      proof
        let b be Ordinal,sb,yb be Surreal such that
A129:   b in D & sb=s.b & yb = y.b;
A130:   b c= d by A129,A123,ORDINAL1:22;
        per cases;
        suppose b=d;
          hence thesis by A127,Th69,A129;
        end;
        suppose b<>d;
          then
A131:     b in d by ORDINAL1:11,A130,XBOOLE_0:def 8;
A132:     sd is (sb,yb,r.b)_term by A131,A129,A128;
A133:     r.b in rng r by A129,A4,FUNCT_1:def 3;
A134:     |. sd - (sb + uReal.(r.b)* No_omega^ yb).|
          infinitely< No_omega^yb by A132,Th73;
A135:     No_omega^ yd infinitely< No_omega^yb
          by Th25,A129,Def11,A5,A131,A124;
          |.uReal.(r.d)* No_omega^ yd.| infinitely< No_omega^yb
          by A127,Th66,A135,Th15;
          then
A136:     |.sd +- (sb + uReal.(r.b)* No_omega^ yb).| +
          |.uReal.(r.d)* No_omega^ yd.|
          infinitely< No_omega^yb by A134,Th18;
          (sd + uReal.(r.d)* No_omega^ yd) +- (sb + uReal.(r.b)* No_omega^ yb)
          = sd +- (sb + uReal.(r.b)* No_omega^ yb) + uReal.(r.d)* No_omega^ yd
          by SURREALR:37;
          then |. c - (sb + uReal.(r.b)* No_omega^ yb).|
          infinitely< No_omega^yb by Th11, A136,Th37;
          hence thesis by A133,Th73;
        end;
      end;
      then
A137: ex x be Surreal st Simpl[x];
A138: for x,y,z be Surreal st x <= y <= z & Simpl[x] & Simpl[z]
      holds Simpl[y] by Th81,A3,XBOOLE_1:18;
      consider sD be uSurreal such that
A139: Simpl[sD] and
A140: for x be uSurreal st Simpl[x] & x <> sD holds born sD in born x
      from Simplest(A137,A138);
      take ssD=s^<%sD%>;
A141: dom <%sD%> = 1 by AFINSQ_1:def 4;
      then dom ssD = (dom s)+^ 1 by ORDINAL4:def 1;
      hence
A142: dom ssD = succ D by A125,A123,ORDINAL2:31;
      let B be Ordinal such that
A143: B in dom ssD;
A144: dom s = dom ssD/\dom s by ORDINAL7:1,A125,A123,A142;
      for o be object st o in dom s holds s.o = ssD.o by ORDINAL4:def 1;
      then
A145: ssD|D = s by A144,FUNCT_1:46,A125,A123;
A146: s|D = s by A125,A123;
      per cases by A142,A143,ORDINAL1:8;
      suppose
A147:   B = D;
        ssD,y,r simplest_on_position D
        proof
          let sa be Surreal such that
A148:     sa = ssD.D;
          0 in dom <%sD%> by A141,TARSKI:def 1,CARD_1:49;
          then ssD.(D+^0) = <%sD%>.0 = sD by A125,A123,ORDINAL4:def 1;
          then
A149:     sa = sD by A148,ORDINAL2:27;
          thus 0 = D implies sa = 0_No by A123;
          assume 0<>D;
          thus sa in_meets_terms ssD,y,r,D by A149,A139,A145,A146,Th75;
          let x be uSurreal such that
A150:     x in_meets_terms ssD,y,r,D & x <> sa;
          thus born sa in born x by A140,A149,A150,A145,A146,Th75;
        end;
        hence thesis by A147;
      end;
      suppose
A151:   B in D;
        then
A152:   s|succ B,y,r simplest_on_position B by A125,A126,A123,Th80;
        ssD|succ B = s|succ B by A151,ORDINAL1:21,A145,RELAT_1:74;
        hence thesis by A152,Th80;
      end;
    end;
  end;
  for D be Ordinal holds P[D] from ORDINAL1:sch 2(A1);
  hence thesis;
end;
