reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem Th80:
  for V being ComplexLinearSpace, v being VECTOR of V, L being
  C_Linear_Combination of V st L is convex & Carrier L = {v} holds ( ex r being
  Real st r = L.v & r = 1 ) & Sum L = L.v * v
proof
  let V be ComplexLinearSpace;
  let v be VECTOR of V;
  let L be C_Linear_Combination of V;
  assume that
A1: L is convex and
A2: Carrier L = {v};
  reconsider L as C_Linear_Combination of {v} by A2,Def4;
  consider F being FinSequence of the carrier of V such that
A3: F is one-to-one & rng F = Carrier L and
A4: ex f being FinSequence of REAL st len f = len F & Sum f = 1 & for n
  being Nat st n in dom f holds f.n = L.(F.n) & f.n >= 0 by A1;
A5: F = <*v*> by A2,A3,FINSEQ_3:97;
  consider f be FinSequence of REAL such that
A6: len f = len F and
A7: Sum f = 1 and
A8: for n being Nat st n in dom f holds f.n = L.(F.n) & f.n >= 0 by A4;
  reconsider r = f/.1 as Element of REAL;
  card Carrier L = 1 by A2,CARD_1:30;
  then len F = 1 by A3,FINSEQ_4:62;
  then
A9: dom f = Seg 1 by A6,FINSEQ_1:def 3;
  then
A10: 1 in dom f;
  then
A11: f.1 = f/.1 by PARTFUN1:def 6;
  then
A12: f = <* r *> by A9,FINSEQ_1:def 8;
  f.1 = L.(F.1) by A8,A10;
  then r = L.v by A11,A5,FINSEQ_1:def 8;
  hence thesis by A7,A12,Th14,FINSOP_1:11;
end;
