
theorem Th83:
for f be nonnegative Function of [:NAT,NAT:],ExtREAL,
    seq be ExtREAL_sequence st
 (for m be Element of NAT holds seq.m = lim_inf ProjMap2(f,m))
  holds Sum seq <= lim_inf lim_in_cod2(Partial_Sums_in_cod2 f)
proof
   let f be nonnegative Function of [:NAT,NAT:],ExtREAL,
       seq be ExtREAL_sequence;
   assume
A1: for m be Element of NAT holds seq.m = lim_inf ProjMap2(f,m);
A2:for m be Element of NAT holds
    for N,n be Element of NAT st n>=N holds
     (inferior_realsequence ProjMap2(f,m)).N <= f.(n,m)
   proof
    let m be Element of NAT;
    let N,n be Element of NAT;
    assume n >= N; then
A4: (inferior_realsequence ProjMap2(f,m)).N
     <= (inferior_realsequence ProjMap2(f,m)).n by RINFSUP2:7;
    (inferior_realsequence ProjMap2(f,m)).n <= (ProjMap2(f,m)).n
       by RINFSUP2:8; then
    (inferior_realsequence ProjMap2(f,m)).n <= f.(n,m) by MESFUNC9:def 7;
    hence (inferior_realsequence ProjMap2(f,m)).N <= f.(n,m)
      by A4,XXREAL_0:2;
   end;
   deffunc F(Element of NAT) = inferior_realsequence ProjMap2(f,$1);
   deffunc G(Element of NAT,Element of NAT)
     = (inferior_realsequence ProjMap2(f,$2)).$1;
   consider g be Function of [:NAT,NAT:],ExtREAL such that
A5: for n be Element of NAT for m be Element of NAT holds
     g.(n,m) = G(n,m) from BINOP_1:sch 4;
   now let z be object;
    per cases;
    suppose z in dom g; then
     consider n,m be object such that
D1:   n in NAT & m in NAT & z = [n,m] by ZFMISC_1:def 2;
     reconsider n,m as Element of NAT by D1;
     g.(n,m) = (inferior_realsequence ProjMap2(f,m)).n by A5; then
     consider Y be non empty Subset of ExtREAL such that
D2:   Y = {ProjMap2(f,m).k where k is Nat : n<=k}
    & g.z = inf Y by D1,RINFSUP2:def 6;
     for x be ExtReal st x in Y holds 0 <= x
     proof
      let x be ExtReal;
      assume x in Y; then
      ex k be Nat st x = ProjMap2(f,m).k & n <= k by D2;
      hence 0 <= x by SUPINF_2:51;
     end; then
     0 is LowerBound of Y by XXREAL_2:def 2;
     hence 0 <= g.z by D2,XXREAL_2:def 4;
    end;
    suppose not z in dom g;
     hence 0 <= g.z by FUNCT_1:def 2;
    end;
   end; then
   g is nonnegative by SUPINF_2:51; then
   reconsider g as nonnegative without-infty Function of [:NAT,NAT:],ExtREAL;
A6:for m be Element of NAT holds
    for N,n be Element of NAT st n>=N holds
    (Partial_Sums_in_cod2 g).(N,m) <= (Partial_Sums_in_cod2 f).(n,m)
   proof
    let m be Element of NAT;
    let N,n be Element of NAT;
    assume A7: n >= N;
    defpred P[Nat] means
     (Partial_Sums_in_cod2 g).(N,$1) <= (Partial_Sums_in_cod2 f).(n,$1);
A8: (Partial_Sums_in_cod2 g).(N,0) = g.(N,0) by DefCSM
     .= (inferior_realsequence ProjMap2(f,0)).N by A5;
    (Partial_Sums_in_cod2 f).(n,0) = f.(n,0) by DefCSM; then
A9: P[0] by A2,A7,A8;
A10:for k be Nat st P[k] holds P[k+1]
    proof
     let k be Nat;
     reconsider k1=k as Element of NAT by ORDINAL1:def 12;
     assume A11: P[k];
     g.(N,k1+1) = (inferior_realsequence ProjMap2(f,k1+1)).N by A5; then
A12: g.(N,k1+1) <= f.(n,k1+1) by A2,A7;
     (Partial_Sums_in_cod2 g).(N,k+1)
      = (Partial_Sums_in_cod2 g).(N,k) + g.(N,k1+1)
   & (Partial_Sums_in_cod2 f).(n,k+1)
      = (Partial_Sums_in_cod2 f).(n,k) + f.(n,k1+1) by DefCSM;
     hence P[k+1] by A11,A12,XXREAL_3:36;
    end;
    for k be Nat holds P[k] from NAT_1:sch 2(A9,A10);
    hence thesis;
   end;
A13:for m be Element of NAT holds
    for N,n be Element of NAT st n>=N holds
     (Partial_Sums_in_cod2 g).(N,m)
       <= (inferior_realsequence(lim_in_cod2(Partial_Sums_in_cod2 f))).n
   proof
    let m be Element of NAT;
    let N,n be Element of NAT;
    assume A14: n>=N;
    consider Y be non empty Subset of ExtREAL such that
A15: Y = {ProjMap2(Partial_Sums_in_cod2 f,m).k where k is Nat : n <= k}
   & (inferior_realsequence(ProjMap2(Partial_Sums_in_cod2 f,m))).n = inf Y
       by RINFSUP2:def 6;
    for x be ExtReal st x in Y holds (Partial_Sums_in_cod2 g).(N,m) <= x
    proof
     let x be ExtReal;
     assume x in Y; then
     consider k be Nat such that
A17:  x = ProjMap2(Partial_Sums_in_cod2 f,m).k & n<=k by A15;
     reconsider k1=k as Element of NAT by ORDINAL1:def 12;
A18: N <= k1 by A14,A17,XXREAL_0:2;
     x = (Partial_Sums_in_cod2 f).(k1,m) by A17,MESFUNC9:def 7;
     hence (Partial_Sums_in_cod2 g).(N,m) <= x by A6,A18;
    end; then
    (Partial_Sums_in_cod2 g).(N,m) is LowerBound of Y by XXREAL_2:def 2; then
A19:(Partial_Sums_in_cod2 g).(N,m)
      <= (inferior_realsequence(ProjMap2(Partial_Sums_in_cod2 f,m))).n
       by A15,XXREAL_2:def 4;
    consider Z be non empty Subset of ExtREAL such that
A20: Z = {(lim_in_cod2(Partial_Sums_in_cod2 f)).k where k is Nat : n <= k}
   & (inferior_realsequence(lim_in_cod2(Partial_Sums_in_cod2 f))).n = inf Z
       by RINFSUP2:def 6;
    for z be ExtReal st z in Z ex y be ExtReal st y in Y & y <= z
    proof
     let z be ExtReal;
     assume z in Z; then
     consider j be Nat such that
A21:  z = (lim_in_cod2(Partial_Sums_in_cod2 f)).j & n <= j by A20;
     reconsider j1=j as Element of NAT by ORDINAL1:def 12;
     z = lim ProjMap1(Partial_Sums_in_cod2 f,j1) by A21,D1DEF6; then
A23: z = sup ProjMap1(Partial_Sums_in_cod2 f,j1) by RINFSUP2:37;
     set y = ProjMap2(Partial_Sums_in_cod2 f,m).j1;
     take y;
     y = (Partial_Sums_in_cod2 f).(j1,m) by MESFUNC9:def 7
      .= ProjMap1(Partial_Sums_in_cod2 f,j1).m by MESFUNC9:def 6;
     hence y in Y & y <= z by A15,A21,A23,RINFSUP2:23;
    end; then
    inf Y <= inf Z by XXREAL_2:64;
    hence thesis by A15,A20,A19,XXREAL_0:2;
   end;
   defpred Q[Nat] means
   for m be Element of NAT st m = $1 holds
    (Partial_Sums seq).m = lim ProjMap2(Partial_Sums_in_cod2 g,m);
   now let m be Element of NAT;
    assume A24: m = 0; then
    (Partial_Sums seq).m = seq.0 by MESFUNC9:def 1
     .= lim_inf ProjMap2(f,0) by A1
     .= sup inferior_realsequence ProjMap2(f,0) by RINFSUP2:def 9; then
A26:(Partial_Sums seq).m
      = lim inferior_realsequence ProjMap2(f,0) by RINFSUP2:37;
    now let n be Element of NAT;
     ProjMap2(Partial_Sums_in_cod2 g,0).n
      = (Partial_Sums_in_cod2 g).(n,0) by MESFUNC9:def 7
     .= g.(n,0) by DefCSM
     .= (inferior_realsequence ProjMap2(f,0)).n by A5;
     hence (inferior_realsequence ProjMap2(f,0)).n
        = ProjMap2(Partial_Sums_in_cod2 g,0).n;
    end;
    hence (Partial_Sums seq).m = lim ProjMap2(Partial_Sums_in_cod2 g,m)
      by A24,A26,FUNCT_2:63;
   end; then
A28:Q[0];
P1:for m be Element of NAT holds
    ProjMap2(Partial_Sums_in_cod2 g,m) is convergent
   proof
    let m be Element of NAT;
    for j,i be Nat st i<=j holds
     ProjMap2(Partial_Sums_in_cod2 g,m).i
       <= ProjMap2(Partial_Sums_in_cod2 g,m).j
    proof
     let j,i be Nat;
     reconsider i1=i, j1=j as Element of NAT by ORDINAL1:def 12;
     assume B2: i <= j;
B3:  ProjMap2(Partial_Sums_in_cod2 g,m).i1 = (Partial_Sums_in_cod2 g).(i,m)
   & ProjMap2(Partial_Sums_in_cod2 g,m).j1 = (Partial_Sums_in_cod2 g).(j,m)
         by MESFUNC9:def 7;
     defpred R[Nat] means
      (Partial_Sums_in_cod2 g).(i,$1) <= (Partial_Sums_in_cod2 g).(j,$1);
B4:  (Partial_Sums_in_cod2 g).(i,0) = g.(i,0) by DefCSM
      .= (inferior_realsequence ProjMap2(f,0)).i1 by A5;
     (Partial_Sums_in_cod2 g).(j,0) = g.(j,0) by DefCSM
      .= (inferior_realsequence ProjMap2(f,0)).j1 by A5; then
B5:  R[0] by B2,B4,RINFSUP2:7;
B6:  for l be Nat st R[l] holds R[l+1]
     proof
      let l be Nat;
      reconsider l1=l as Element of NAT by ORDINAL1:def 12;
      assume B7: R[l];
      g.(i,l+1) = (inferior_realsequence ProjMap2(f,l1+1)).i1
    & g.(j,l+1) = (inferior_realsequence ProjMap2(f,l1+1)).j1 by A5; then
B8:   g.(i,l+1) <= g.(j,l+1) by B2,RINFSUP2:7;
      (Partial_Sums_in_cod2 g).(i,l+1)
       = (Partial_Sums_in_cod2 g).(i,l) + g.(i,l+1)
    & (Partial_Sums_in_cod2 g).(j,l+1)
       = (Partial_Sums_in_cod2 g).(j,l) + g.(j,l+1) by DefCSM;
      hence R[l+1] by B7,B8,XXREAL_3:36;
     end;
     for l be Nat holds R[l] from NAT_1:sch 2(B5,B6);
     hence thesis by B3;
    end; then
    ProjMap2(Partial_Sums_in_cod2 g,m) is non-decreasing by RINFSUP2:7;
    hence ProjMap2(Partial_Sums_in_cod2 g,m) is convergent by RINFSUP2:37;
   end;
A29:for k be Nat st Q[k] holds Q[k+1]
   proof
    let k be Nat;
    reconsider k1=k as Element of NAT by ORDINAL1:def 12;
    assume A30: Q[k];
    now let m be Element of NAT;
     assume B00: m = k+1; then
B0:  (Partial_Sums seq).m
      = (Partial_Sums seq).k + seq.(k+1) by MESFUNC9:def 1
     .= lim ProjMap2(Partial_Sums_in_cod2 g,k1) + seq.(k+1) by A30
     .= lim ProjMap2(Partial_Sums_in_cod2 g,k1) + lim_inf ProjMap2(f,k+1)
          by A1;
B1:  lim_inf ProjMap2(f,k+1)
      = sup inferior_realsequence ProjMap2(f,k1+1) by RINFSUP2:def 9
     .= lim inferior_realsequence ProjMap2(f,k1+1) by RINFSUP2:37;
B9:  ProjMap2(Partial_Sums_in_cod2 g,k1) is convergent by P1;
B10: inferior_realsequence ProjMap2(f,k1+1) is convergent
       by RINFSUP2:37;
     for n be object st n in dom(inferior_realsequence ProjMap2(f,k1+1))
      holds 0. <= (inferior_realsequence ProjMap2(f,k1+1)).n
     proof
      let n be object;
      assume n in dom(inferior_realsequence ProjMap2(f,k1+1)); then
      g.(n,k1+1) = (inferior_realsequence ProjMap2(f,k1+1)).n by A5;
      hence thesis by SUPINF_2:51;
     end; then
C2:  inferior_realsequence ProjMap2(f,k1+1) is nonnegative by SUPINF_2:52;
     for i be Nat holds
      ProjMap2(Partial_Sums_in_cod2 g,m).i
       = ProjMap2(Partial_Sums_in_cod2 g,k1).i
        + (inferior_realsequence ProjMap2(f,k1+1)).i
     proof
      let i be Nat;
      reconsider i1=i as Element of NAT by ORDINAL1:def 12;
      ProjMap2(Partial_Sums_in_cod2 g,m).i1
       = (Partial_Sums_in_cod2 g).(i,m) by MESFUNC9:def 7
      .= (Partial_Sums_in_cod2 g).(i,k) + g.(i,k+1) by B00,DefCSM
      .= ProjMap2(Partial_Sums_in_cod2 g,k1).i1 + g.(i,k+1) by MESFUNC9:def 7;
      hence thesis by A5;
     end;
     hence (Partial_Sums seq).m = lim ProjMap2(Partial_Sums_in_cod2 g,m)
       by B0,B1,B9,B10,C2,MESFUNC9:11;
    end;
    hence Q[k+1];
   end;
A30: for k be Nat holds Q[k] from NAT_1:sch 2(A28,A29);
A31:
   for m be Nat holds
    (Partial_Sums seq).m <= lim_inf lim_in_cod2(Partial_Sums_in_cod2 f)
   proof
    let m be Nat;
    reconsider m1=m as Element of NAT by ORDINAL1:def 12;
A32:for n be Nat holds
     ProjMap2(Partial_Sums_in_cod2 g,m1).n
      <= (inferior_realsequence(lim_in_cod2(Partial_Sums_in_cod2 f))).n
    proof
     let n be Nat;
     reconsider n1=n as Element of NAT by ORDINAL1:def 12;
     ProjMap2(Partial_Sums_in_cod2 g,m1).n1
      = (Partial_Sums_in_cod2 g).(n,m) by MESFUNC9:def 7;
     hence ProjMap2(Partial_Sums_in_cod2 g,m1).n
      <= (inferior_realsequence(lim_in_cod2(Partial_Sums_in_cod2 f))).n
           by A13;
    end;
A33:ProjMap2(Partial_Sums_in_cod2 g,m1) is convergent by P1;
    (inferior_realsequence(lim_in_cod2(Partial_Sums_in_cod2 f)))
      is convergent by RINFSUP2:37; then
    lim ProjMap2(Partial_Sums_in_cod2 g,m1)
     <= lim (inferior_realsequence(lim_in_cod2(Partial_Sums_in_cod2 f)))
       by A32,A33,RINFSUP2:38; then
    (Partial_Sums seq).m
     <= lim (inferior_realsequence(lim_in_cod2(Partial_Sums_in_cod2 f)))
       by A30; then
    (Partial_Sums seq).m
     <= sup (inferior_realsequence(lim_in_cod2(Partial_Sums_in_cod2 f)))
       by RINFSUP2:37;
    hence thesis by RINFSUP2:def 9;
   end;
   for m be object st m in dom seq holds 0<=seq.m
   proof
    let m be object;
    assume m in dom seq; then
    reconsider m1=m as Element of NAT;
E1: seq.m = lim_inf ProjMap2(f,m1) by A1
      .= sup inferior_realsequence ProjMap2(f,m1) by RINFSUP2:def 9;
    for n be object st n in dom(inferior_realsequence ProjMap2(f,m1))
     holds 0. <= (inferior_realsequence ProjMap2(f,m1)).n
    proof
     let n be object;
     assume n in dom(inferior_realsequence ProjMap2(f,m1)); then
     g.(n,m1) = (inferior_realsequence ProjMap2(f,m1)).n by A5;
     hence thesis by SUPINF_2:51;
    end; then
    (inferior_realsequence ProjMap2(f,m1)).0 >= 0 by SUPINF_2:51,52;
    hence thesis by E1,RINFSUP2:23;
   end; then
   seq is nonnegative by SUPINF_2:52; then
   Partial_Sums seq is non-decreasing by MESFUNC9:16; then
   lim (Partial_Sums seq) <= lim_inf lim_in_cod2(Partial_Sums_in_cod2 f)
     by A31,MESFUNC9:9,RINFSUP2:37;
   hence thesis by MESFUNC9:def 3;
end;
