reserve x, r for Real;
reserve A for symmetrical Subset of COMPLEX;
reserve F,G for PartFunc of REAL, REAL;
reserve B for symmetrical Subset of REAL;

theorem Th83:
  B c= dom (cosec) implies cosec is_odd_on B
proof
  assume
A1: B c= dom (cosec);
  then
A2: dom(cosec|B) = B by RELAT_1:62;
A3: for x st x in B holds cosec.(-x) = -cosec.x
  proof
    let x;
    assume
A4: x in B;
    then -x in B by Def1;
    then cosec.(-x)=(sin.(-x))" by A1,RFUNCT_1:def 2
      .=(-sin.x)" by SIN_COS:30
      .=-(sin.x)" by XCMPLX_1:222
      .=-cosec.x by A1,A4,RFUNCT_1:def 2;
    hence thesis;
  end;
  for x st x in dom(cosec|B) & -x in dom(cosec|B) holds cosec|B.(-x)=-
  cosec|B.x
  proof
    let x;
    assume that
A5: x in dom(cosec|B) and
A6: -x in dom(cosec|B);
    cosec|B.(-x)=cosec|B/.(-x) by A6,PARTFUN1:def 6
      .=cosec/.(-x) by A1,A2,A6,PARTFUN2:17
      .=cosec.(-x) by A1,A6,PARTFUN1:def 6
      .=-cosec.x by A3,A5
      .=-cosec/.x by A1,A5,PARTFUN1:def 6
      .=-cosec|B/.x by A1,A2,A5,PARTFUN2:17
      .=-cosec|B.x by A5,PARTFUN1:def 6;
    hence thesis;
  end;
  then cosec|B is with_symmetrical_domain quasi_odd by A2;
  hence thesis by A1;
end;
