
theorem Th83:
  for G1, G2 being _Graph
  for G3 being DSimpleGraph of G1, G4 being DSimpleGraph of G2
  for G5 being DGraphComplement of G1, G6 being DGraphComplement of G2
  st G4 is G3-Disomorphic holds G6 is G5-Disomorphic
proof
  let G1, G2 be _Graph;
  let G3 be DSimpleGraph of G1, G4 be DSimpleGraph of G2;
  let G5 be DGraphComplement of G1, G6 be DGraphComplement of G2;
  A1: G5 is DGraphComplement of G3 & G6 is DGraphComplement of G4 by Th82;
  assume G4 is G3-Disomorphic;
  then consider f being directed PVertexMapping of G3, G4 such that
    A2: f is Disomorphism by GLIB_011:50;
  A3: the_Vertices_of G3 = the_Vertices_of G5 &
    the_Vertices_of G4 = the_Vertices_of G6 by A1, Th80;
  then reconsider g = f as PartFunc of the_Vertices_of G5, the_Vertices_of G6;
  now
    let v,w,e be object;
    assume A4: v in dom g & w in dom g & e DJoins v,w,G5;
    then A5: v <> w by GLIB_000:136;
    then A6: g.v <> g.w by A2, A4, FUNCT_1:def 4;
    A7: not ex e3 being object st e3 DJoins v,w,G3 by A1, A3, A4, A5, Th80;
    thus ex e6 being object st e6 DJoins g.v,g.w,G6
    proof
      assume A8: not ex e6 being object st e6 DJoins g.v,g.w,G6;
      g.v in rng f & g.w in rng f by A4, FUNCT_1:3;
      then consider e4 being object such that
        A9: e4 DJoins g.v,g.w,G4 by A1, A6, A8, Th80;
      consider e3 being object such that
        A10: e3 DJoins v,w,G3 by A2, A4, A9, GLIB_011:def 4;
      thus contradiction by A7, A10;
    end;
  end;
  then reconsider g as directed PVertexMapping of G5, G6 by GLIB_011:4;
  now
    let v,w,e6 be object;
    assume A11: v in dom g & w in dom g & e6 DJoins g.v,g.w,G6;
    A12: g.v <> g.w by A11, GLIB_000:136;
    g.v in rng f & g.w in rng f by A11, FUNCT_1:3;
    then A13: not ex e4 being object st e4 DJoins g.v,g.w,G4
      by A1, A11, A12, Th80;
    thus ex e5 being object st e5 DJoins v,w,G5
    proof
      assume not ex e5 being object st e5 DJoins v,w,G5;
      then consider e3 being object such that
        A14: e3 DJoins v,w,G3 by A1, A3, A11, A12, Th80;
      consider e4 being object such that
        A15: e4 DJoins f.v,f.w,G4 by A11, A14, GLIB_011:def 2;
      thus contradiction by A13, A15;
    end;
  end;
  then g is Dcontinuous by GLIB_011:def 4;
  hence thesis by A2, A3, GLIB_011:50;
end;
