reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th83:
  for G being GroupWithOperators of O, H being StableSubgroup of G
, FG being FinSequence of the carrier of G, FH being FinSequence of the carrier
of H, I be FinSequence of INT st FG=FH & len FG = len I holds Product(FG |^ I)
  = Product(FH |^ I)
proof
  let G be GroupWithOperators of O;
  let H be StableSubgroup of G;
  let FG be FinSequence of the carrier of G;
  let FH be FinSequence of the carrier of H;
  let I be FinSequence of INT;
  assume
A1: FG=FH & len FG = len I;
  defpred P[Nat] means for FG being FinSequence of the carrier of G, FH being
FinSequence of the carrier of H, I being FinSequence of INT st len FG = $1 & FG
  =FH & len FG = len I holds Product(FG |^ I) = Product(FH |^ I);
A2: now
    let n be Nat;
    assume
A3: P[n];
    thus P[n+1]
    proof
      let FG be FinSequence of the carrier of G;
      let FH be FinSequence of the carrier of H;
      let I be FinSequence of INT;
      assume
A4:   len FG = n+1;
      then consider
      FGn be FinSequence of the carrier of G, g be Element of G such
      that
A5:   FG = FGn^<*g*> by FINSEQ_2:19;
A6:   len FG = len FGn + len <*g*> by A5,FINSEQ_1:22;
      then
A7:   n+1 = len FGn + 1 by A4,FINSEQ_1:40;
      assume that
A8:   FG=FH and
A9:   len FG = len I;
      consider FHn be FinSequence of the carrier of H, h be Element of H such
      that
A10:  FH = FHn^<*h*> by A4,A8,FINSEQ_2:19;
      consider In be FinSequence of INT, i be Element of INT such that
A11:  I = In^<*i*> by A4,A9,FINSEQ_2:19;
      set FG1=<*g*>;
      set I1=<*i*>;
      len I = len In + len <*i*> by A11,FINSEQ_1:22;
      then
A12:  n+1 = len In + 1 by A4,A9,FINSEQ_1:40;
A13:  len FH = len FHn + len <*h*> by A10,FINSEQ_1:22;
      then
A14:  FH.(n+1)=(FHn^<*h*>).(len FHn +1) by A4,A8,A10,FINSEQ_1:40
        .= h by FINSEQ_1:42;
A15:  n+1 = len FHn + 1 by A4,A8,A13,FINSEQ_1:40;
A16:  FG.(n+1)=(FGn^<*g*>).(len FGn +1) by A4,A5,A6,FINSEQ_1:40
        .= g by FINSEQ_1:42;
A17:  now
        reconsider H9=H as Subgroup of G by Def7;
        reconsider h9=h as Element of H9;
        g|^i = h9|^i by A8,A16,A14,GROUP_4:2;
        hence g|^i = h|^i;
      end;
      len FG1 = 1 by FINSEQ_1:40
        .=len I1 by FINSEQ_1:40;
      then
A18:  Product(FG |^ I) = Product((FGn |^ In)^(FG1 |^ I1)) by A11,A5,A12,A7,
GROUP_4:19
        .= Product(FGn |^ In) * Product(FG1 |^ I1) by GROUP_4:5;
      set FH1=<*h*>;
A19:  len FH1 = 1 by FINSEQ_1:40
        .=len I1 by FINSEQ_1:40;
A20:  Product(FG1 |^ I1) = Product(<*g*>|^<*@i*>)
        .= Product <*g|^i*> by GROUP_4:22
        .= h|^i by A17,GROUP_4:9
        .= Product <*h|^i*> by GROUP_4:9
        .= Product(<*h*>|^<*@i*>) by GROUP_4:22
        .= Product(FH1 |^ I1);
      FGn = FHn by A8,A5,A10,A16,A14,FINSEQ_1:33;
      then Product(FGn |^ In) = Product(FHn |^ In) by A3,A12,A15;
      then Product(FG |^ I) = Product(FHn |^ In) * Product(FH1 |^ I1) by A18
,A20,Th3
        .= Product((FHn |^ In)^(FH1 |^ I1)) by GROUP_4:5
        .= Product((FHn^FH1) |^ (In^I1)) by A12,A15,A19,GROUP_4:19;
      hence thesis by A11,A10;
    end;
  end;
A21: P[0]
  proof
    let FG be FinSequence of the carrier of G;
    let FH be FinSequence of the carrier of H;
    let I be FinSequence of INT;
    assume
A22: len FG = 0;
    then len(FG |^ I) = 0 by GROUP_4:def 3;
    then FG |^ I = <*> the carrier of G;
    then
A23: Product(FG |^ I) = 1_G by GROUP_4:8;
    assume that
A24: FG=FH and
    len FG = len I;
    len(FH |^ I) = 0 by A22,A24,GROUP_4:def 3;
    then FH |^ I = <*> the carrier of H;
    then Product(FH |^ I) = 1_H by GROUP_4:8;
    hence thesis by A23,Th4;
  end;
  for n being Nat holds P[n] from NAT_1:sch 2(A21,A2);
  hence thesis by A1;
end;
