reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;

theorem Th67:
  for f being Function of TOP-REAL n,R^1 st (for q holds f.q=|.q.|
  ) holds f is continuous
proof
  let f be Function of TOP-REAL n,R^1;
A1: the TopStruct of TOP-REAL n = TopSpaceMetr(Euclid n) by EUCLID:def 8;
  then reconsider
  f1=f as Function of TopSpaceMetr(Euclid n),TopSpaceMetr(RealSpace
  ) by TOPMETR:def 6;
  assume
A2: for q holds f.q=|.q.|;
  now
    let r be Real,u be Element of Euclid n,u1 be Element
    of RealSpace;
    assume that
A3: r>0 and
A4: u1=f1.u;
    set s1=r;
    for w being Element of Euclid n, w1 being Element of RealSpace st w1=
    f1.w & dist(u,w)<s1 holds dist(u1,w1)<r
    proof
      let w be Element of Euclid n, w1 be Element of RealSpace;
      assume that
A5:   w1=f1.w and
A6:   dist(u,w)<s1;
      reconsider tu=u1,tw=w1 as Real;
      reconsider qw=w,qu=u as Point of TOP-REAL n by TOPREAL3:8;
A7:   dist(u1,w1)=(the distance of RealSpace).(u1,w1)
        .=|.tu-tw.| by METRIC_1:def 12;
A8:   tu=|.qu.| by A2,A4;
      w1=|.qw.| by A2,A5;
      then dist(u,w)=|.qu-qw.| & dist(u1,w1)<=|.qu-qw.| by A7,A8,Th3,
JGRAPH_1:28;
      hence thesis by A6,XXREAL_0:2;
    end;
    hence ex s being Real st s>0 & for w being Element of Euclid n, w1
being Element of RealSpace st w1=f1.w & dist(u,w)<s holds dist(u1,w1)<r by A3;
  end;
  then f1 is continuous by UNIFORM1:3;
  hence thesis by A1,PRE_TOPC:32,TOPMETR:def 6;
end;
