reserve a,b,c,h for Integer;
reserve k,m,n for Nat;
reserve i,j,z for Integer;
reserve p for Prime;

theorem Th83:
  card (multiples(2) /\ seq(k,2*m)) = m
  proof
    set M = multiples(2);
    defpred P[Nat] means card (M /\ seq(k,2*$1)) = $1;
A1: P[0]
    proof
      seq(k,2*0) = {} by CALCUL_2:2;
      hence thesis;
    end;
A2: for z being Nat st P[z] holds P[z+1]
    proof
      let z be Nat;
      assume
A3:   P[z];
      seq(k,2*(z+1)) = seq(k,2*z+1+1)
      .= seq(k,2*z+1) \/ {k+(2*z+1)+1} by CALCUL_2:5
      .= seq(k,2*z) \/ {k+2*z+1} \/ {k+(2*z+1)+1} by CALCUL_2:5;
      then
A4:   M /\ seq(k,2*(z+1)) = M /\ (seq(k,2*z) \/ ({k+2*z+1} \/ {k+(2*z+1)+1}))
      by XBOOLE_1:4
      .= M /\ seq(k,2*z) \/ M /\ ({k+2*z+1} \/ {k+(2*z+1)+1}) by XBOOLE_1:23;
A5:   {k+2*z+1} \/ {k+(2*z+1)+1} = {k+2*z+1,k+(2*z+1)+1} by ENUMSET1:1;
      seq(k,2*z) misses {k+2*z+1,k+2*z+2} by Th74;
      then card (M /\ seq(k,2*z) \/ M /\ ({k+2*z+1} \/ {k+(2*z+1)+1}))
      = card (M /\ seq(k,2*z)) + card (M /\ ({k+2*z+1} \/ {k+(2*z+1)+1}))
      by A5,XBOOLE_1:76,CARD_2:40;
      hence thesis by A3,A4,A5,Th82;
    end;
    for z being Nat holds P[z] from NAT_1:sch 2(A1,A2);
    hence thesis;
  end;
