reserve L for Lattice,
  p,q,r for Element of L,
  p9,q9,r9 for Element of L.:,
  x, y for set;
reserve I,J for Ideal of L,
  F for Filter of L;
reserve D for non empty Subset of L,
  D9 for non empty Subset of L.:;
reserve D1,D2 for non empty Subset of L,
  D19,D29 for non empty Subset of L.:;
reserve B for B_Lattice,
  IB,JB for Ideal of B,
  a,b for Element of B;
reserve a9 for Element of (B qua Lattice).:;
reserve P for non empty ClosedSubset of L,
  o1,o2 for BinOp of P;

theorem Th84:
  L is C_Lattice & L is modular & p [= q implies latt (L,[#p,q#]) is C_Lattice
proof
  assume that
A1: L is C_Lattice and
A2: L is modular and
A3: p [= q;
  reconsider K = latt (L,[#p,q#]) as bounded Lattice by A3,Th82;
  K is complemented
  proof
    let b9 be Element of K;
    reconsider b = b9 as Element of L by Th68;
    consider a being Element of L such that
A4: a is_a_complement_of b by A1,LATTICES:def 19;
A5: a"/\"b = Bottom L by A4;
A6: a"\/"b = Top L by A4;
A7: carr(K) = [#p,q#] by Th72;
    then
A8: b [= q by A3,Th62;
    a"/\"q [= q by LATTICES:6;
    then p [= p"\/"(a"/\"q) & p"\/"(a"/\"q) [= q by A3,FILTER_0:6,LATTICES:5;
    then reconsider a9 = p"\/"(a"/\"q) as Element of K by A3,A7,Th62;
    take a9;
A9: p [= b by A3,A7,Th62;
    thus a9"\/"b9 = (p"\/"(a"/\"q))"\/"b by Th73
      .= b"\/"p"\/"(a"/\" q) by LATTICES:def 5
      .= b"\/"(a"/\"q) by A9
      .= (Top L)"/\"q by A2,A6,A8
      .= q by A1
      .= Top K by A3,Th82;
    hence b9"\/"a9 = Top K;
    thus a9"/\"b9 = (p"\/"(a"/\"q))"/\"b by Th73
      .= p"\/"((a"/\"q)"/\"b) by A2,A9
      .= p"\/"(q"/\"Bottom L) by A5,LATTICES:def 7
      .= p"\/"Bottom L by A1
      .= p by A1
      .= Bottom K by A3,Th82;
    hence thesis;
  end;
  hence thesis;
end;
