reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;

theorem Th68:
  ex f being Function of TOP-REAL n,R^1 st (for q holds f.q=|.q.|)
  & f is continuous
proof
  defpred P[object,object] means (ex q st q=$1 & $2=|.q.|);
A1: for x being object st x in (the carrier of TOP-REAL n)
ex y being object st P[x,y]
  proof
    let x be object;
    assume x in the carrier of TOP-REAL n;
    then reconsider q3=x as Point of TOP-REAL n;
    take |.q3.|;
    thus thesis;
  end;
  consider f1 being Function such that
A2: dom f1 = (the carrier of TOP-REAL n) &
  for x being object st x in (the carrier of
  TOP-REAL n) holds P[x,f1.x] from CLASSES1:sch 1(A1);
  rng f1 c= the carrier of R^1
  proof
    let z be object;
    assume z in rng f1;
    then consider xz being object such that
A3: xz in dom f1 and
A4: z=f1.xz by FUNCT_1:def 3;
    consider q4 being Point of TOP-REAL n such that
A5:   q4=xz & f1.xz=|.q4.| by A2,A3;
     z in REAL by A4,A5,XREAL_0:def 1;
    hence thesis by TOPMETR:17;
  end;
  then reconsider f2=f1 as Function of TOP-REAL n,R^1 by A2,FUNCT_2:def 1
,RELSET_1:4;
A6: for q holds f1.q=|.q.|
  proof
    let q;
    ex q2 st q2=q & f1.q=|.q2.| by A2;
    hence thesis;
  end;
  then f2 is continuous by Th67;
  hence thesis by A6;
end;
