
theorem Th97:
  for a, b being Ordinal, x being object
  holds (omega -exponent CantorNF a).x c= (omega -exponent CantorNF(a(+)b)).x
proof
  let a, b be Ordinal, x be object;
  set E1 = omega -exponent CantorNF a, E2 = omega -exponent CantorNF b;
  set L1 = omega -leading_coeff CantorNF a;
  set L2 = omega -leading_coeff CantorNF b;
  set C0 = CantorNF(a (+) b);
  assume not E1.x c= (omega -exponent C0).x;
  then A1: (omega -exponent C0).x in E1.x by ORDINAL1:16;
  then x in dom E1 by FUNCT_1:def 2;
  then reconsider x as Ordinal;
  defpred P[Ordinal] means (omega -exponent C0).$1 in E1.$1;
  A2: ex z being Ordinal st P[z]
  proof
    take x;
    thus thesis by A1;
  end;
  consider y being Ordinal such that
    A3: P[y] & for z being Ordinal st P[z] holds y c= z
    from ORDINAL1:sch 1(A2);
  A4: rng(omega -exponent C0) = rng E1 \/ rng E2 by Th76;
  A5: y in dom E1 by A3, FUNCT_1:def 2;
  then E1.y in rng E1 by FUNCT_1:3;
  then E1.y in rng(omega -exponent C0) by A4, XBOOLE_1:7, TARSKI:def 3;
  then consider z being object such that
    A6: z in dom(omega -exponent C0) & (omega -exponent C0).z = E1.y
    by FUNCT_1:def 3;
  reconsider z as Ordinal by A6;
  A7: z in dom C0 by A6, Def1;
  A8: z in y
  proof
    assume not z in y;
    then per cases by ORDINAL1:14;
    suppose z = y;
      hence contradiction by A3, A6;
    end;
    suppose A9: y in z;
      then omega-exponent(C0.z) in omega-exponent(C0.y) by A7, ORDINAL5:def 11;
      then E1.y in omega-exponent(C0.y) by A6, A7, Def1;
      hence contradiction by A3, A7, A9, Def1, ORDINAL1:10;
    end;
  end;
  A10: y in dom CantorNF a by A5, Def1;
  then omega -exponent((CantorNF a).y) in omega -exponent((CantorNF a).z)
    by A8, ORDINAL5:def 11;
  then E1.y in omega -exponent((CantorNF a).z) by A10, Def1;
  then E1.y in E1.z by A8, A10, Def1, ORDINAL1:10;
  then y c= z by A3, A6;
  then z in z by A8;
  hence contradiction;
end;
