reserve A,B for Ordinal,
        o for object,
        x,y,z for Surreal,
        n for Nat,
        r,r1,r2 for Real;

theorem Th84:
  for r be Sequence of REAL for y,s be Sequence
      for A,B be Ordinal st B c= A holds
   s,y|A,r|A simplest_on_position B iff s,y,r simplest_on_position B
proof
  let r be Sequence of REAL;
  let y,s be Sequence;
  let A,B be Ordinal such that
A1: B c= A;
  thus s,y|A,r|A simplest_on_position B implies s,y,r simplest_on_position B
  proof
    assume
A2: s,y|A,r|A simplest_on_position B;
    let sa be Surreal such that
A3: sa = s.B;
    thus 0 = B implies sa = 0_No by A3,A2;
    assume
A4: B<>0;
    sa in_meets_terms s,y|A,r|A,B by A3,A2;
    hence sa in_meets_terms s,y,r,B by A1,Th83;
    let x be uSurreal;
    assume
A5: x in_meets_terms s,y,r,B & x <> sa;
    then x in_meets_terms s,y|A,r|A,B by A1,Th83;
    hence thesis by A2,A3,A4,A5;
  end;
  assume
A6: s,y,r simplest_on_position B;
  let sa be Surreal such that
A7: sa = s.B;
  thus 0 = B implies sa = 0_No by A7,A6;
  assume
A8: B<>0;
  sa in_meets_terms s,y,r,B by A7,A6;
  hence sa in_meets_terms s,y|A,r|A,B by A1,Th83;
  let x be uSurreal;
  assume
A9: x in_meets_terms s,y|A,r|A,B & x <> sa;
  then x in_meets_terms s,y,r,B by A1,Th83;
  hence thesis by A6,A7,A8,A9;
end;
