reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th85:
  for N1,N2 being strict StableSubgroup of H1, N19,N29 being
  strict StableSubgroup of G st N1 = N19 & N2 = N29 holds N19 * N29 = N1 * N2
proof
  let N1,N2 be strict StableSubgroup of H1;
  let N19,N29 be strict StableSubgroup of G;
  set X={g * h where g,h is Element of G: g in carr N19 & h in carr N29};
  set Y={g * h where g,h is Element of H1: g in carr N1 & h in carr N2};
  assume
A1: N1=N19 & N2=N29;
A2: now
    N2 is Subgroup of H1 by Def7;
    then
A3: the carrier of N2 c= the carrier of H1 by GROUP_2:def 5;
    let x be object;
    assume x in X;
    then consider g,h be Element of G such that
A4: x=g*h and
A5: g in carr N19 & h in carr N29;
    N1 is Subgroup of H1 by Def7;
    then the carrier of N1 c= the carrier of H1 by GROUP_2:def 5;
    then reconsider g,h as Element of H1 by A1,A5,A3;
    x=g*h by A4,Th3;
    hence x in Y by A1,A5;
  end;
  now
    let x be object;
    assume x in Y;
    then consider g,h be Element of H1 such that
A6: x=g*h and
A7: g in carr N1 & h in carr N2;
    reconsider g,h as Element of G by Th2;
    x=g*h by A6,Th3;
    hence x in X by A1,A7;
  end;
  hence thesis by A2,TARSKI:2;
end;
