
theorem Th85:
  for X be non empty set, S be SigmaField of X, M be sigma_Measure
  of S, f,g be PartFunc of X,ExtREAL st (ex E be Element of S st E = dom f & E=
dom g & f is E-measurable & g is E-measurable) & f is nonnegative & g is
  nonnegative & (for x be Element of X st x in dom g holds g.x <= f.x) holds
  integral+(M,g) <= integral+(M,f)
proof
  let X be non empty set, S be SigmaField of X, M be sigma_Measure of S, f,g
  be PartFunc of X,ExtREAL such that
A1: ex A be Element of S st A = dom f & A= dom g & f is A-measurable
  & g is A-measurable and
A2: f is nonnegative and
A3: g is nonnegative and
A4: for x be Element of X st x in dom g holds g.x <= f.x;
  consider G be Functional_Sequence of X,ExtREAL, L be ExtREAL_sequence such
  that
A5: for n be Nat holds G.n is_simple_func_in S & dom(G.n) = dom g and
A6: for n be Nat holds G.n is nonnegative and
A7: for n,m be Nat st n <=m holds for x be Element of X st x in dom g
  holds (G.n).x <= (G.m).x and
A8: for x be Element of X st x in dom g holds G#x is convergent & lim(G
  #x) = g.x and
A9: for n be Nat holds L.n=integral'(M,G.n) and
  L is convergent and
A10: integral+(M,g)=lim L by A1,A3,Def15;
  consider F be Functional_Sequence of X,ExtREAL, K be ExtREAL_sequence such
  that
A11: for n be Nat holds F.n is_simple_func_in S & dom(F.n) = dom f and
A12: for n be Nat holds F.n is nonnegative and
A13: for n,m be Nat st n <=m holds for x be Element of X st x in dom f
  holds (F.n).x <= (F.m).x and
A14: for x be Element of X st x in dom f holds (F#x) is convergent & lim
  (F#x) = f.x and
A15: for n be Nat holds K.n=integral'(M,F.n) and
  K is convergent and
A16: integral+(M,f)=lim(K) by A1,A2,Def15;
  consider A be Element of S such that
A17: A = dom f and
A18: A= dom g and
  f is A-measurable and
  g is A-measurable by A1;
A19: for x be Element of X st x in A holds lim(G#x)=sup rng(G#x)
  proof
    let x be Element of X;
    assume
A20: x in A;
    now
      let n,m be Nat;
      assume
A21:  n<=m;
A22:  (G#x).m=(G.m).x by Def13;
      (G#x).n=(G.n).x by Def13;
      hence (G#x).n <= (G#x).m by A18,A7,A20,A21,A22;
    end;
    hence thesis by Th54;
  end;
A23: for n0 be Nat holds L is convergent & sup rng L=lim L
  proof
    let n0 be Nat;
    set ff = G.n0;
A24: dom ff = A by A18,A5;
A25: for x be Element of X st x in dom ff holds G#x is convergent & ff.x
    <= lim(G#x)
    proof
      let x be Element of X such that
A26:  x in dom ff;
A27:  (G#x).n0 <= sup rng (G#x) by Th56;
      ff.x =(G#x).n0 by Def13;
      hence thesis by A18,A8,A19,A24,A26,A27;
    end;
    ff is_simple_func_in S by A5;
    then consider FF be ExtREAL_sequence such that
A28: for n be Nat holds FF.n = integral'(M,G.n) and
A29: FF is convergent and
A30: sup rng FF = lim FF and
    integral'(M,ff) <= lim FF by A18,A5,A6,A7,A24,A25,Th75;
    now
      let n be Element of NAT;
      thus FF.n = integral'(M,G.n) by A28
        .=L.n by A9;
    end;
    then FF=L by FUNCT_2:63;
    hence thesis by A29,A30;
  end;
  for n0 be Nat holds K is convergent & sup rng K = lim K & L.n0 <= lim K
  proof
    let n0 be Nat;
    set gg = G.n0;
A31: gg is nonnegative by A6;
A32: dom gg = A by A18,A5;
A33: for x be Element of X st x in dom gg holds F#x is convergent & gg.x
    <= lim(F#x)
    proof
      let x be Element of X such that
A34:  x in dom gg;
A35:  (G#x).n0 <= sup rng (G#x) by Th56;
      gg.x =(G#x).n0 by Def13;
      then gg.x <= lim(G#x) by A19,A32,A34,A35;
      then
A36:  gg.x <= g.x by A18,A8,A32,A34;
      g.x <= f.x by A1,A4,A17,A32,A34;
      then g.x <= lim(F#x) by A17,A14,A32,A34;
      hence thesis by A17,A14,A32,A34,A36,XXREAL_0:2;
    end;
    gg is_simple_func_in S by A5;
    then consider GG be ExtREAL_sequence such that
A37: for n be Nat holds GG.n = integral'(M,F.n) and
A38: GG is convergent and
A39: sup rng GG =lim GG and
A40: integral'(M,gg) <= lim GG by A17,A11,A12,A13,A32,A31,A33,Th75;
    now
      let n be Element of NAT;
      GG.n = integral'(M,F.n) by A37;
      hence GG.n = K.n by A15;
    end;
    then GG=K by FUNCT_2:63;
    hence thesis by A9,A38,A39,A40;
  end;
  hence thesis by A16,A10,A23,Th57;
end;
