reserve E,V for set, G,G1,G2 for _Graph, c,c1,c2 for Cardinal, n for Nat;
reserve f for VColoring of G;
reserve g for EColoring of G;

theorem Th86:
  g is proper iff for e1,e2,v,w1,w2 being object
    st e1 Joins v,w1,G & e2 Joins v,w2,G & g.e1 = g.e2 holds e1 = e2
proof
  hereby
    assume A1: g is proper;
    let e1,e2,v,w1,w2 be object;
    assume A2: e1 Joins v,w1,G & e2 Joins v,w2,G & g.e1 = g.e2;
    then reconsider v as Vertex of G by GLIB_000:13;
    e1 in v.edgesInOut() & e2 in v.edgesInOut() by A2, GLIB_000:62;
    hence e1 = e2 by A1, A2, Th85;
  end;
  assume A3: for e1,e2,v,w1,w2 being object
    st e1 Joins v,w1,G & e2 Joins v,w2,G & g.e1 = g.e2 holds e1 = e2;
  now
    let v be Vertex of G, e1,e2 be object;
    assume A4: e1 in v.edgesInOut() & e2 in v.edgesInOut() & g.e1 = g.e2;
    then consider v1 being Vertex of G such that
      A5: e1 Joins v,v1,G by GLIB_000:64;
    consider v2 being Vertex of G such that
      A6: e2 Joins v,v2,G by A4, GLIB_000:64;
    thus e1 = e2 by A3, A4, A5, A6;
  end;
  hence thesis by Th85;
end;
