 reserve G, A for Group;
 reserve phi for Homomorphism of A,AutGroup(G);
 reserve G, A for Group;
 reserve phi for Homomorphism of A,AutGroup(G);
reserve G1,G2 for Group;

theorem LmINTGroupOrd3: :: TH91
  for n being non zero Nat
  for g1 being Element of INT.Group n st g1 = 1
  for i being Nat
  holds g1 |^ i = i mod n
proof
  let n be non zero Nat;
  let g1 be Element of INT.Group n;
  assume A1: g1 = 1;
  defpred P[Nat] means
  g1 |^ $1 = $1 mod n;
  A2: P[0]
  proof
    thus g1 |^ 0 = 1_(INT.Group n) by GROUP_1:25
                .= 0 by GR_CY_1:14
                .= 0 mod n by NAT_D:26;
  end;
  A3: for i being Nat st P[i] holds P[i + 1]
  proof
    let i be Nat;
    assume A4: P[i];
    (i mod n) < n & (i mod n) in NAT by NAT_D:1;
    then A5: (i mod n) in Segm n by NAT_1:44;
    per cases by NAT_1:53;
    suppose A6: n = 1;
      then INT.Group n is trivial;
      then A7: g1 |^ (i + 1) = 1_(INT.Group n)
                            .= 0 by GR_CY_1:14;
      ((i + 1) mod n) = ((i + 1) mod 1) by A6
                     .= ((1*(i + 1)) mod 1)
                     .= 0 by NAT_D:13;
      hence thesis by A7;
    end;
    suppose n > 1;
      then A7: 1 in Segm n by NAT_1:44;
      g1 |^ (i + 1) = (g1 |^ i)*g1 by GROUP_1:34
                   .= (addint n).(i mod n, 1) by A1,A4,Th75
                   .= ((i mod n) + 1) mod n by A5,A7,GR_CY_1:def 4
                   .= (i + 1) mod n by NAT_D:22;
      hence P[i + 1];
    end;
  end;

  for i being Nat holds P[i] from NAT_1:sch 2(A2,A3);
  hence thesis;
end;
