reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th86:
  for N1,N2 being strict StableSubgroup of H1, N19,N29 being
strict StableSubgroup of G st N1 = N19 & N2 = N29 holds N19 "\/" N29 = N1 "\/"
  N2
proof
  let N1,N2 be strict StableSubgroup of H1;
  reconsider S2 = the_stable_subgroup_of(N1*N2) as StableSubgroup of G by Th11;
  let N19,N29 be strict StableSubgroup of G;
  set S1 = the_stable_subgroup_of(N19*N29);
  set X1={B where B is Subset of G : ex H being strict StableSubgroup of G st
  B = the carrier of H & N19*N29 c= carr H};
  set X2={B where B is Subset of H1 : ex H being strict StableSubgroup of H1
  st B = the carrier of H & N1*N2 c= carr H};
A1: N19 "\/" N29 = the_stable_subgroup_of(N19*N29) & N1 "\/" N2 =
  the_stable_subgroup_of(N1*N2) by Th29;
A2: the carrier of the_stable_subgroup_of(N19*N29) = meet X1 & the carrier
  of the_stable_subgroup_of(N1*N2) = meet X2 by Th27;
  assume
A3: N1=N19 & N2=N29;
  now
    let x be object;
    assume x in X2;
    then consider B be Subset of H1 such that
A4: x=B and
A5: ex H being strict StableSubgroup of H1 st B = the carrier of H &
    N1 *N2 c= carr H;
    now
      consider H be strict StableSubgroup of H1 such that
A6:   B = the carrier of H & N1*N2 c= carr H by A5;
      reconsider H as strict StableSubgroup of G by Th11;
      take H;
      thus B = the carrier of H & N19*N29 c= carr H by A3,A6,Th85;
    end;
    hence x in X1 by A4;
  end;
  then
A7: X2 c= X1;
  now
    set x9=carr H1;
    reconsider x=x9 as set;
    take x;
    now
      set H=(Omega).H1;
      take H;
      thus x9 = the carrier of H;
      thus N1*N2 c= carr H;
    end;
    hence x in X2;
  end;
  then
A8: meet X1 c= meet X2 by A7,SETFAM_1:6;
  now
    let x be object;
    assume
A9: x in the carrier of the_stable_subgroup_of(N1*N2);
    the_stable_subgroup_of(N1*N2) is Subgroup of H1 by Def7;
    then the carrier of the_stable_subgroup_of(N1*N2) c= the carrier of H1 by
GROUP_2:def 5;
    then reconsider g=x as Element of H1 by A9;
    g in the_stable_subgroup_of(N1*N2) by A9,STRUCT_0:def 5;
    then consider
    F be FinSequence of the carrier of H1, I be FinSequence of INT, C
    be Subset of H1 such that
A10: C = the_stable_subset_generated_by (N1*N2, the action of H1) and
A11: len F = len I and
A12: rng F c= C and
A13: Product(F |^ I) = g by Th24;
    now
      N2 is Subgroup of H1 by Def7;
      then 1_H1 in N2 by GROUP_2:46;
      then
A14:  1_H1 in carr N2 by STRUCT_0:def 5;
      let x be object;
      assume
A15:  x in the_stable_subset_generated_by (N1*N2, the action of H1);
      then reconsider a=x as Element of H1;
      N1 is Subgroup of H1 by Def7;
      then 1_H1 in N1 by GROUP_2:46;
      then
A16:  1_H1 in carr N1 by STRUCT_0:def 5;
      1_H1=1_H1*1_H1 by GROUP_1:def 4;
      then
A17:  1_H1 in carr N1 * carr N2 by A16,A14;
      then consider F be FinSequence of O, h be Element of N1*N2 such that
A18:  Product(F,the action of H1).h = a by A15,Lm30;
      H1 is Subgroup of G by Def7;
      then
A19:  the carrier of H1 c= the carrier of G by GROUP_2:def 5;
      then reconsider a as Element of G;
A20:  h in N1*N2 by A17;
      reconsider h as Element of N19*N29 by A3,Th85;
      now
        let o be Element of O;
        let f1 be Function of the carrier of H1,the carrier of H1;
        let f2 be Function of the carrier of G,the carrier of G;
        assume that
A21:    f1=(the action of H1).o and
A22:    f2=(the action of G).o;
        per cases;
        suppose
          o in O;
          then H1^o = f1 & G^o = f2 by A21,A22,Def6;
          hence f1 = f2|the carrier of H1 by Def7;
        end;
        suppose
          not o in O;
          then not o in dom the action of H1;
          hence f1 = f2|the carrier of H1 by A21,FUNCT_1:def 2;
        end;
      end;
      then Product(F,the action of H1) = Product(F,the action of G)|the
      carrier of H1 by A19,Th84;
      then
A23:  Product(F,the action of G).h = a by A18,A20,FUNCT_1:49;
      N19*N29 is non empty by A3,A20,Th85;
      hence x in the_stable_subset_generated_by (N19*N29, the action of G) by
A23,Lm30;
    end;
    then the_stable_subset_generated_by (N1*N2, the action of H1) c=
    the_stable_subset_generated_by (N19*N29, the action of G);
    then
A24: rng F c= the_stable_subset_generated_by (N19*N29, the action of G )
    by A10,A12;
    reconsider g as Element of G by Th2;
    H1 is Subgroup of G by Def7;
    then the carrier of H1 c= the carrier of G by GROUP_2:def 5;
    then rng F c= the carrier of G;
    then reconsider F as FinSequence of the carrier of G by FINSEQ_1:def 4;
    Product(F |^ I) = g by A11,A13,Th83;
    then
A25: g in the_stable_subgroup_of(N19*N29) by A11,A24,Th24;
    assume not x in the carrier of the_stable_subgroup_of(N19*N29);
    hence contradiction by A25,STRUCT_0:def 5;
  end;
  then meet X2 c= meet X1 by A2;
  then the carrier of S1 = the carrier of S2 by A2,A8,XBOOLE_0:def 10;
  hence thesis by A1,Lm4;
end;
