reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;

theorem Th70:
  for g being Function of I[01],TOP-REAL n,a being Real st g is
continuous & |.g/.0 .|<=a & a<=|.g/.1 .| holds ex s being Point of I[01] st
  |.g/.s.|=a
proof
  reconsider I=1 as Point of I[01] by BORSUK_1:40,XXREAL_1:1;
A1: 0 in [.0,1 .] by XXREAL_1:1;
  reconsider o=0 as Point of I[01] by BORSUK_1:40,XXREAL_1:1;
  let g be Function of I[01],TOP-REAL n,a be Real;
  assume that
A2: g is continuous and
A3: |.g/.0 .|<=a & a<=|.g/.1.|;
  consider f being Function of I[01],R^1 such that
A4: for t being Point of I[01] holds f.t=|.g.t.| and
A5: f is continuous by A2,Th69;
A6: f.0=|.g.o.| by A4
    .=|.g/.0 .| by FUNCT_2:def 13;
  set c = |.g/.0 .|, b=|.g/.1.|;
A7: 1 in the carrier of I[01] by BORSUK_1:40,XXREAL_1:1;
A8: f.1=|.g.I.| by A4
    .=|.g/.1.| by FUNCT_2:def 13;
  per cases by A3,XXREAL_0:1;
  suppose
    c < a & a<b;
    then consider rc being Real such that
A9: f.rc =a and
A10: 0<rc & rc<1 by A5,A6,A8,TOPMETR:20,TOPREAL5:6;
    reconsider rc1=rc as Point of I[01] by A10,BORSUK_1:40,XXREAL_1:1;
A11: rc in the carrier of I[01] by A10,BORSUK_1:40,XXREAL_1:1;
    |.g/.rc.|= |. g.rc1 .| by FUNCT_2:def 13
      .=a by A4,A9;
    hence thesis by A11;
  end;
  suppose
    c =a;
    hence thesis by A1,BORSUK_1:40;
  end;
  suppose
    a=b;
    hence thesis by A7;
  end;
end;
