reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem
  for V being ComplexLinearSpace, v1,v2 being VECTOR of V, L being
  C_Linear_Combination of {v1,v2} st v1 <> v2 & L is convex holds ( ex r1, r2
being Real st r1 = L.v1 & r2 = L.v2 &r1 >= 0 & r2 >= 0 )& Sum L = L.v1 *
  v1 + L.v2 * v2
proof
  let V be ComplexLinearSpace;
  let v1,v2 be VECTOR of V;
  let L be C_Linear_Combination of {v1,v2};
  assume that
A1: v1 <> v2 and
A2: L is convex;
A3: Carrier L c= {v1,v2} by Def4;
A4: Carrier L <> {} by A2,Th77;
  ex r1, r2 being Real st r1 = L.v1 & r2 = L.v2 & r1 >= 0 & r2 >= 0
  proof
    per cases by A3,A4,ZFMISC_1:36;
    suppose
A5:   Carrier L = {v1};
      then not v2 in Carrier(L) by A1,TARSKI:def 1;
      then
A6:   0 = L.v2;
      ex r being Real st r = L.v1 & r = 1 by A2,A5,Th80;
      hence thesis by A6;
    end;
    suppose
A7:   Carrier L = {v2};
      then not v1 in Carrier L by A1,TARSKI:def 1;
      then
A8:   0=L.v1;
      ex r being Real st r =L.v2 & r = 1 by A2,A7,Th80;
      hence thesis by A8;
    end;
    suppose
      Carrier L = {v1,v2};
      then ex r1,r2 being Real st r1=L.v1 & r2 = L.v2 & r1 + r2 = 1 & r1 >= 0
      & r2 >=0 by A1,A2,Th81;
      hence thesis;
    end;
  end;
  hence thesis by A1,Th15;
end;
