reserve a, b, c, d, x, y, z for Complex;
reserve r for Real;

theorem
  angle(a,b,c)+angle(b,c,a)+angle(c,a,b) = PI or angle(a,b,c)+angle(b,c,
  a)+angle(c,a,b) = 5*PI iff a <> b & a <> c & b <> c
proof
  hereby
    assume
A1: angle(a,b,c)+angle(b,c,a)+angle(c,a,b) = PI or angle(a,b,c)+angle(
    b,c,a)+angle(c,a,b) = 5*PI;
    per cases by A1;
    suppose
A2:   angle(a,b,c)+angle(b,c,a)+angle(c,a,b) = PI;
      thus a <> b & a <> c & b <> c
      proof
        assume
A3:     not (a <> b & a <> c & b <> c);
        per cases by A3;
        suppose
A4:       a=b;
A5:       angle(a,c,a) = 0 by Th77;
          not (angle(a,a,c) = 0 & angle(c,a,a) = 0) by A2,A4,Th77,COMPTRIG:5;
          hence contradiction by A2,A4,A5,Th78,COMPTRIG:5;
        end;
        suppose
A6:       a=c;
A7:       angle(a,b,a) = 0 by Th77;
          not (angle(a,a,b) = 0 & angle(b,a,a) = 0) by A2,A6,Th77,COMPTRIG:5;
          hence contradiction by A2,A6,A7,Th78,COMPTRIG:5;
        end;
        suppose
A8:       b=c;
A9:       angle(b,a,b) = 0 by Th77;
          not (angle(a,b,b) = 0 & angle(b,b,a) = 0) by A2,A8,Th77,COMPTRIG:5;
          hence contradiction by A2,A8,A9,Th78,COMPTRIG:5;
        end;
      end;
    end;
    suppose
A10:  angle(a,b,c)+angle(b,c,a)+angle(c,a,b) = 5*PI;
A11:  (2+2)*PI < 5*PI by COMPTRIG:5,XREAL_1:68;
      then
A12:  2*PI+2*PI < 5*PI;
      thus a <> b & a <> c & b <> c
      proof
        assume
A13:    not (a <> b & a <> c & b <> c);
        per cases by A13;
        suppose
          a=b;
          then angle(b,c,a) = 0 by Th77;
          then
A14:      angle(a,b,c)+angle(b,c,a) < 2*PI by Th68;
          angle(c,a,b) < 2*PI by Th68;
          hence contradiction by A10,A12,A14,XREAL_1:8;
        end;
        suppose
A15:      b=c;
          angle(a,b,c) < 2*PI & angle(b,c,a) < 2*PI by Th68;
          then
A16:      angle(a,b,c)+angle(b,c,a) < 2*PI+2*PI by XREAL_1:8;
          angle(c,a,b) = 0 by A15,Th77;
          hence contradiction by A10,A11,A16;
        end;
        suppose
          a=c;
          then angle(a,b,c) = 0 by Th77;
          then
A17:      angle(a,b,c)+angle(b,c,a) < 2*PI by Th68;
          angle(c,a,b) < 2*PI by Th68;
          hence contradiction by A10,A12,A17,XREAL_1:8;
        end;
      end;
    end;
  end;
  assume that
A18: a <> b and
A19: a <> c and
A20: b <> c;
  per cases by XXREAL_0:1;
  suppose
A21: angle(a,b,c) = 0;
    angle(b,c,a)+angle(c,a,b) = PI
    proof
      per cases by A18,A19,A20,A21,Th85;
      suppose
        angle(b,c,a) = 0 & angle(c,a,b) = PI;
        hence thesis;
      end;
      suppose
        angle(b,c,a) = PI & angle(c,a,b) = 0;
        hence thesis;
      end;
    end;
    hence thesis by A21;
  end;
  suppose
A22: 0 <> angle(a,b,c) & angle(a,b,c) < PI;
    0 <= angle(a,b,c) by Th68;
    hence thesis by A18,A20,A22,Th82;
  end;
  suppose
A23: 0 <> angle(a,b,c) & angle(a,b,c) = PI;
    then angle(b,c,a) = 0 by A18,A20,Th84;
    hence thesis by A18,A20,A23,Th84;
  end;
  suppose
    0 <> angle(a,b,c) & angle(a,b,c) > PI;
    hence thesis by A18,A20,Th83;
  end;
end;
