reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem
  for V being ComplexLinearSpace, v1,v2,v3 being VECTOR of V, L being
  C_Linear_Combination of {v1,v2,v3} st v1 <> v2 & v2 <> v3 & v3 <> v1 & L is
convex holds ( ex r1, r2, r3 being Real st r1 = L.v1 & r2 = L.v2 & r3 =
L.v3 & r1 + r2 + r3 = 1 & r1 >= 0 & r2 >= 0 & r3 >= 0 ) & Sum L = L.v1 * v1 + L
  .v2 * v2 + L.v3 * v3
proof
  let V be ComplexLinearSpace;
  let v1,v2,v3 be VECTOR of V;
  let L be C_Linear_Combination of {v1,v2,v3};
  assume that
A1: v1 <> v2 and
A2: v2 <> v3 and
A3: v3 <> v1 and
A4: L is convex;
A5: Carrier L c= {v1,v2,v3} by Def4;
A6: Carrier L <> {} by A4,Th77;
  ex r1, r2, r3 being Real st r1 = L.v1 & r2 = L.v2 & r3 = L.v3 &
  r1 + r2 + r3 = 1 & r1 >= 0 & r2 >= 0 & r3 >= 0
  proof
    per cases by A5,A6,ZFMISC_1:118;
    suppose
A7:   Carrier L = {v1};
      then not v2 in Carrier L by A1,TARSKI:def 1;
      then
A8:   0 = L.v2;
A9:   1 + 0 + 0 =1;
      not v3 in Carrier L by A3,A7,TARSKI:def 1;
      then
A10:  0 = L.v3;
      ex r being Real st r = L.v1 & r = 1 by A4,A7,Th80;
      hence thesis by A8,A10,A9;
    end;
    suppose
A11:  Carrier L = {v2};
      then not v1 in Carrier L by A1,TARSKI:def 1;
      then
A12:  0 = L.v1;
A13:  0 + 1 + 0 =1;
      not v3 in Carrier L by A2,A11,TARSKI:def 1;
      then
A14:  0 = L.v3;
      ex r being Real st r = L.v2 & r = 1 by A4,A11,Th80;
      hence thesis by A12,A14,A13;
    end;
    suppose
A15:  Carrier L = {v3};
      then not v1 in Carrier L by A3,TARSKI:def 1;
      then
A16:  0 = L.v1;
A17:  0 + 0 + 1 =1;
      not v2 in Carrier L by A2,A15,TARSKI:def 1;
      then
A18:  0 = L.v2;
      ex r being Real st r = L.v3 & r = 1 by A4,A15,Th80;
      hence thesis by A16,A18,A17;
    end;
    suppose
A19:  Carrier L = {v1,v2};
      set r3 = 0;
      not v3 in {v where v is Element of V : L.v <> 0} by A2,A3,A19,
TARSKI:def 2;
      then
A20:  r3 = L.v3;
      consider r1, r2 being Real such that
A21:  r1 = L.v1 & r2 = L.v2 and
A22:  r1 + r2 = 1 and
A23:  r1 >= 0 & r2 >= 0 by A1,A4,A19,Th81;
      r1 + r2 + r3 = 1 by A22;
      hence thesis by A21,A23,A20;
    end;
    suppose
A24:  Carrier L = {v2,v3};
      set r1 = 0;
      not v1 in Carrier L by A1,A3,A24,TARSKI:def 2;
      then
A25:  r1 = L.v1;
      consider r2,r3 being Real such that
A26:  r2 = L.v2 & r3 = L.v3 and
A27:  r2 + r3 = 1 and
A28:  r2 >= 0 & r3 >= 0 by A2,A4,A24,Th81;
      r1 + r2 + r3 = 1 by A27;
      hence thesis by A26,A28,A25;
    end;
    suppose
A29:  Carrier L = {v1,v3};
      set r2 = 0;
      not v2 in Carrier(L) by A1,A2,A29,TARSKI:def 2;
      then
A30:  r2 = L.v2;
      consider r1, r3 being Real such that
A31:  r1 = L.v1 & r3 = L.v3 and
A32:  r1 + r3 = 1 and
A33:  r1 >= 0 & r3 >= 0 by A3,A4,A29,Th81;
      r1 + r2 + r3 = 1 by A32;
      hence thesis by A31,A33,A30;
    end;
    suppose
      Carrier L = {v1,v2,v3};
      hence thesis by A1,A2,A3,A4,Th82;
    end;
  end;
  hence thesis by A1,A2,A3,Lm3;
end;
