reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th88:
  for f being Homomorphism of G,H holds for g being Homomorphism
  of H,I holds the carrier of Ker(g*f) = f"(the carrier of Ker g)
proof
  let f be Homomorphism of G,H;
  let g be Homomorphism of H,I;
A1: now
    let x be object;
    assume
A2: x in f"(the carrier of Ker g);
    then f.x in the carrier of Ker g by FUNCT_1:def 7;
    then f.x in {b where b is Element of H: g.b = 1_I} by Def21;
    then
A3: ex b be Element of H st b=f.x & g.b = 1_I;
    x in dom f by A2,FUNCT_1:def 7;
    then 1_I = (g*f).x by A3,FUNCT_1:13;
    then x in {a9 where a9 is Element of G: (g*f).a9 = 1_I} by A2;
    hence x in the carrier of Ker(g*f) by Def21;
  end;
A4: dom f = the carrier of G by FUNCT_2:def 1;
  now
    let x be object;
    assume x in the carrier of Ker(g*f);
    then x in {a where a is Element of G: (g*f).a = 1_I} by Def21;
    then consider a be Element of G such that
A5: x=a and
A6: (g*f).a =1_I;
    reconsider b=f.a as Element of H;
    g.b = 1_I by A4,A6,FUNCT_1:13;
    then f.x in {b9 where b9 is Element of H: g.b9 = 1_I} by A5;
    then f.x in the carrier of Ker g by Def21;
    hence x in f"(the carrier of Ker g) by A4,A5,FUNCT_1:def 7;
  end;
  hence thesis by A1,TARSKI:2;
end;
