reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem Th88:
  for f be PartFunc of CNS,RNS st dom f<>{} & (dom f) is compact
& f is_continuous_on (dom f) holds ex x1,x2 be Point of CNS st x1 in dom f & x2
in dom f & ||.f.||/.x1 = upper_bound (rng ||.f.||) & ||.f.||/.x2 = lower_bound
  (rng ||.f.||)
proof
  let f be PartFunc of CNS,RNS such that
A1: dom f <> {} and
A2: dom f is compact and
A3: f is_continuous_on (dom f);
A4: dom f = dom ||.f.|| by NORMSP_0:def 3;
  dom ||.f.|| is compact by A2,NORMSP_0:def 3;
  then
A5: rng ||.f.|| is compact by A3,A4,Th72,Th81;
A6: rng ||.f.|| <> {} by A1,A4,RELAT_1:42;
  then consider x being Element of CNS such that
A7: x in dom ||.f.|| & upper_bound (rng ||.f.||) = ||.f.||.x by A5,PARTFUN1:3
,RCOMP_1:14;
  consider y being Element of CNS such that
A8: y in dom ||.f.|| & lower_bound (rng ||.f.||) = ||.f.||.y by A6,A5,
PARTFUN1:3,RCOMP_1:14;
  take x;
  take y;
  thus thesis by A7,A8,NORMSP_0:def 3,PARTFUN1:def 6;
end;
