reserve A,B for Ordinal,
        o for object,
        x,y,z for Surreal,
        n for Nat,
        r,r1,r2 for Real;

theorem Th88:
  for r be non-zero Sequence of REAL,
       y be strictly_decreasing Surreal-Sequence,
       A be Ordinal st r,y,A name_like x
    holds x in_meets_terms Partial_Sums(r,y),y,r,A
proof
  let r be non-zero Sequence of REAL,
  y be strictly_decreasing Surreal-Sequence,
  A be Ordinal such that
A1: r,y,A name_like x;
  set s=Partial_Sums(r,y);
  let beta be Ordinal,sb,yb be Surreal such that
A2:  beta in A & sb=s.beta & yb = y.beta;
A3: not x == sb & r.beta = omega-r (x - sb) &
  y.beta = omega-y (x - sb) by A2,A1;
A4: not x - sb == 0_No by A2,A1,SURREALR:47;
  then
A5: |.x - sb - No_omega^ yb* uReal.(r.beta).|
  infinitely< |.x - sb.| by A2,A3,Def8;
  |.x + - sb.|, No_omega^ yb are_commensurate by A2,A3,A4,Def7;
  then
A6: |.x - sb - No_omega^ yb* uReal.(r.beta).|
  infinitely< No_omega^ yb by A5,Th16;
A7: x - sb - No_omega^ yb* uReal.(r.beta) =
  x + (- sb - No_omega^ yb* uReal.(r.beta)) by SURREALR:37
  .= x -(sb +No_omega^ yb* uReal.(r.beta)) by SURREALR:40;
  r.beta in rng r by A2,A1,FUNCT_1:def 3;
  hence thesis by A6,A7,Th73;
end;
