
theorem Th896:
digits(2134,10) = <%4,3,1,2%>
proof
  set d=<%4,3,1,2%>;
  set e=<%4*10|^0,3*10|^1,1*10|^2,2*10|^3%>;
  A1: Sum e = Sum (<%4*10|^0,3*10|^1,1*10|^2%>)+Sum(<%2*10|^3%>) by AFINSQ_2:55
  .= Sum (<%4*10|^0,3*10|^1%>)+Sum(<%1*10|^2%>)+Sum(<%2*10|^3%>) by AFINSQ_2:55
  .= ((4*10|^0)+(3*10|^1))+Sum(<%1*10|^2%>)+Sum(<%2*10|^3%>) by AFINSQ_2:54
  .= ((4*10|^0)+(3*10|^1))+(1*10|^2)+Sum(<%2*10|^3%>) by AFINSQ_2:53
  .= ((4*10|^0)+(3*10|^1))+(1*10|^2)+(2*10|^3) by AFINSQ_2:53
  .= 4*1 + 3*(10|^1) + 1*(10|^2) + 2*(10|^3) by NEWTON:4
  .= 4 + 3*10 + 1*(10|^2) + 2*(10|^3) by NEWTON:5
  .= 34 + 1*(10*10) + 2*(10|^3) by POLYEQ_5:1
  .= 34 + 1*(10*10) + 2*(10*10*10) by POLYEQ_5:2
  .= 2134;
  A2: dom d = 4 by AFINSQ_1:84 .= dom e by AFINSQ_1:84;
  now
    let i be Nat;
    assume i in dom d;
    then i in 4 by AFINSQ_1:84;
    then i in {0,1,2,3} by CARD_1:52;
    then i = 0 or i = 1 or i = 2 or i = 3 by ENUMSET1:def 2;
    hence e.i=(d.i)*10|^i;
  end;
  then A3: value(d,10)=2134 by A1,A2,NUMERAL1:def 1;
  len(d) - 1 = 4-1 by AFINSQ_1:84;
  then A4: d.(len(d)-1) <> 0;
  now
    let i be Nat;
    assume i in dom d;
    then i in 4 by AFINSQ_1:84;
    then i in {0,1,2,3} by CARD_1:52;
    then i = 0 or i = 1 or i = 2 or i = 3 by ENUMSET1:def 2;
    hence 0 <= d.i & d.i < 10;
  end;
  hence thesis by A3,A4,NUMERAL1:def 2;
end;
