reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th89:
  for G9 being StableSubgroup of G, H9 being StableSubgroup of H,
  f being Homomorphism of G,H st the carrier of H9 = f.:(the carrier of G9) or
  the carrier of G9 = f"(the carrier of H9) holds f|(the carrier of G9) is
  Homomorphism of G9,H9
proof
  let G9 be StableSubgroup of G;
  let H9 be StableSubgroup of H;
  let f be Homomorphism of G,H;
  set g=f|(the carrier of G9);
  G9 is Subgroup of G by Def7;
  then
A1: the carrier of G9 c= the carrier of G by GROUP_2:def 5;
  then
A2: the carrier of G9 c= dom f by FUNCT_2:def 1;
  then
A3: dom g = the carrier of G9 by RELAT_1:62;
  assume
A4: the carrier of H9 = f.:(the carrier of G9) or the carrier of G9 = f"
  (the carrier of H9);
A5: for x st x in the carrier of G9 holds f.x in the carrier of H9
  proof
    let x;
    assume
A6: x in the carrier of G9;
    per cases by A4;
    suppose
A7:   the carrier of H9 = f.:(the carrier of G9);
      assume not f.x in the carrier of H9;
      hence contradiction by A2,A6,A7,FUNCT_1:def 6;
    end;
    suppose
      the carrier of G9 = f"(the carrier of H9);
      hence thesis by A6,FUNCT_1:def 7;
    end;
  end;
  now
    let y be object;
    assume y in rng g;
    then consider x being object such that
A8: x in dom g and
A9: y = g.x by FUNCT_1:def 3;
A10: x in the carrier of G9 by A2,A8,RELAT_1:62;
    then y = f.x by A9,FUNCT_1:49;
    hence y in the carrier of H9 by A5,A10;
  end;
  then rng g c= the carrier of H9;
  then reconsider g as Function of G9,H9 by A3,RELSET_1:4;
A11: now
    let a9,b9 be Element of G9;
    reconsider a=a9,b=b9 as Element of G by A1;
A12: f.a = g.a9 & f.b = g.b9 by FUNCT_1:49;
    thus g.(a9* b9) = f.(a9*b9) by FUNCT_1:49
      .= f.(a*b) by Th3
      .= f.a * f.b by GROUP_6:def 6
      .= g.a9 * g.b9 by A12,Th3;
  end;
  now
    let o be Element of O;
    let a9 be Element of G9;
    reconsider a=a9 as Element of G by A1;
    thus g.((G9^o).a9) = f.((G9^o).a9) by FUNCT_1:49
      .= f.(((G^o)|the carrier of G9).a9) by Def7
      .= f.((G^o).a) by FUNCT_1:49
      .= (H^o).(f.a) by Def18
      .= (H^o).(g.a9) by FUNCT_1:49
      .= ((H^o)|the carrier of H9).(g.a9) by FUNCT_1:49
      .= (H9^o).(g.a9) by Def7;
  end;
  hence thesis by A11,Def18,GROUP_6:def 6;
end;
