reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;
reserve D for non vertical non horizontal non empty compact Subset of TOP-REAL
  2;

theorem Th73:
  len (GoB SpStSeq D)=2 & width (GoB SpStSeq D)=2 & (SpStSeq D)/.1
=(GoB SpStSeq D)*(1,2) & (SpStSeq D)/.2=(GoB SpStSeq D)*(2,2) & (SpStSeq D)/.3=
(GoB SpStSeq D)*(2,1) & (SpStSeq D)/.4=(GoB SpStSeq D)*(1,1) & (SpStSeq D)/.5=(
  GoB SpStSeq D)*(1,2)
proof
  set f=SpStSeq D;
A1: S-bound L~f < N-bound L~f by SPRECT_1:32;
A2: len f=5 by SPRECT_1:82;
  then
A3: f/.5=f/.1 by FINSEQ_6:def 1;
  4 in Seg len f by A2,FINSEQ_1:1;
  then
A4: 4 in dom f by FINSEQ_1:def 3;
  then 4 in dom (X_axis(f)) by SPRECT_2:15;
  then f/.4 = W-min L~f & (X_axis(f)).4=(f/.4)`1 by GOBOARD1:def 1,SPRECT_1:86;
  then
A5: (X_axis(f)).4=W-bound L~f;
A6: f/.3 = S-max L~f by SPRECT_1:85;
  3 in Seg len f by A2,FINSEQ_1:1;
  then
A7: 3 in dom f by FINSEQ_1:def 3;
  then 3 in dom (X_axis(f)) by SPRECT_2:15;
  then f/.3 = E-min L~f & (X_axis(f)).3=(f/.3)`1 by GOBOARD1:def 1,SPRECT_1:85;
  then
A8: (X_axis(f)).3=E-bound L~f;
A9: f/.(1+1) = N-max L~f by SPRECT_1:84;
  3 in dom (Y_axis(f)) by A7,SPRECT_2:16;
  then (Y_axis(f)).3=(f/.3)`2 by GOBOARD1:def 2;
  then
A10: (Y_axis(f)).3=S-bound L~f by A6;
A11: f/.1 = N-min L~f by SPRECT_1:83;
  1 in Seg len f by A2,FINSEQ_1:1;
  then
A12: 1 in dom f by FINSEQ_1:def 3;
  then 1 in dom (Y_axis(f)) by SPRECT_2:16;
  then (Y_axis(f)).1=(f/.1)`2 by GOBOARD1:def 2;
  then
A13: (Y_axis(f)).1=N-bound L~f by A11;
A14: f/.4 = S-min L~f by SPRECT_1:86;
  2 in Seg len f by A2,FINSEQ_1:1;
  then
A15: 2 in dom f by FINSEQ_1:def 3;
  then 2 in dom (X_axis(f)) by SPRECT_2:15;
  then f/.(1+1) = E-max L~f & (X_axis(f)).2=(f/.2)`1 by GOBOARD1:def 1
,SPRECT_1:84;
  then
A16: (X_axis(f)).2=E-bound L~f;
  4 in dom (Y_axis(f)) by A4,SPRECT_2:16;
  then (Y_axis(f)).4=(f/.4)`2 by GOBOARD1:def 2;
  then
A17: (Y_axis(f)).4=S-bound L~f by A14;
  2 in dom (Y_axis(f)) by A15,SPRECT_2:16;
  then (Y_axis(f)).2=(f/.2)`2 by GOBOARD1:def 2;
  then
A18: (Y_axis(f)).2=N-bound L~f by A9;
A19: {S-bound L~f,N-bound L~f} c= rng (Y_axis(f))
  proof
    let z be object;
    assume
A20: z in {S-bound L~f,N-bound L~f};
    now
      per cases by A20,TARSKI:def 2;
      case
A21:    z=S-bound L~f;
        4 in dom (Y_axis(f)) by A4,SPRECT_2:16;
        hence thesis by A17,A21,FUNCT_1:def 3;
      end;
      case
A22:    z=N-bound L~f;
        2 in dom (Y_axis(f)) by A15,SPRECT_2:16;
        hence thesis by A18,A22,FUNCT_1:def 3;
      end;
    end;
    hence thesis;
  end;
A23: f/.1 = W-max L~f by SPRECT_1:83;
  1 in dom (X_axis(f)) by A12,SPRECT_2:15;
  then (X_axis(f)).1=(f/.1)`1 by GOBOARD1:def 1;
  then
A24: (X_axis(f)).1=W-bound L~f by A23;
A25: {W-bound L~f,E-bound L~f} c= rng (X_axis(f))
  proof
    let z be object;
    assume
A26: z in {W-bound L~f,E-bound L~f};
    now
      per cases by A26,TARSKI:def 2;
      case
A27:    z=W-bound L~f;
        1 in dom (X_axis(f)) by A12,SPRECT_2:15;
        hence thesis by A24,A27,FUNCT_1:def 3;
      end;
      case
A28:    z=E-bound L~f;
        2 in dom (X_axis(f)) by A15,SPRECT_2:15;
        hence thesis by A16,A28,FUNCT_1:def 3;
      end;
    end;
    hence thesis;
  end;
A29: GoB f = GoB(Incr(X_axis(f)),Incr(Y_axis(f))) by GOBOARD2:def 2;
  5 in Seg len f by A2,FINSEQ_1:1;
  then
A30: 5 in dom f by FINSEQ_1:def 3;
  then 5 in dom (X_axis(f)) by SPRECT_2:15;
  then (X_axis(f)).5=(f/.5)`1 by GOBOARD1:def 1;
  then
A31: (X_axis(f)).5=W-bound L~f by A23,A3;
  rng (X_axis(f)) c= {W-bound L~f,E-bound L~f}
  proof
    let z be object;
    assume z in rng (X_axis(f));
    then consider u being object such that
A32: u in dom (X_axis(f)) and
A33: z=(X_axis(f)).u by FUNCT_1:def 3;
    reconsider mu=u as Element of NAT by A32;
    u in dom f by A32,SPRECT_2:15;
    then u in Seg len f by FINSEQ_1:def 3;
    then 1<=mu & mu<=5 by A2,FINSEQ_1:1;
    then
A34: mu=1+0 or ... or mu=1+4 by NAT_1:62;
    per cases by A34;
    suppose
      mu=1;
      hence thesis by A24,A33,TARSKI:def 2;
    end;
    suppose
      mu=2;
      hence thesis by A16,A33,TARSKI:def 2;
    end;
    suppose
      mu=3;
      hence thesis by A8,A33,TARSKI:def 2;
    end;
    suppose
      mu=4;
      hence thesis by A5,A33,TARSKI:def 2;
    end;
    suppose
      mu=5;
      hence thesis by A31,A33,TARSKI:def 2;
    end;
  end;
  then
A35: rng (X_axis(f))={W-bound L~f,E-bound L~f} by A25;
  then
A36: rng (Incr (X_axis(f)))={W-bound L~f,E-bound L~f} by SEQ_4:def 21;
  5 in dom (Y_axis(f)) by A30,SPRECT_2:16;
  then (Y_axis(f)).5=(f/.5)`2 by GOBOARD1:def 2;
  then
A37: (Y_axis(f)).5=N-bound L~f by A11,A3;
  rng (Y_axis(f)) c= {S-bound L~f,N-bound L~f}
  proof
    let z be object;
    assume z in rng (Y_axis(f));
    then consider u being object such that
A38: u in dom (Y_axis(f)) and
A39: z=(Y_axis(f)).u by FUNCT_1:def 3;
    reconsider mu=u as Element of NAT by A38;
    u in dom f by A38,SPRECT_2:16;
    then u in Seg len f by FINSEQ_1:def 3;
    then 1<=mu & mu<=5 by A2,FINSEQ_1:1;
    then
A40: mu=1+0 or ... or mu=1+4 by NAT_1:62;
    per cases by A40;
    suppose
      mu=1;
      hence thesis by A13,A39,TARSKI:def 2;
    end;
    suppose
      mu=2;
      hence thesis by A18,A39,TARSKI:def 2;
    end;
    suppose
      mu=3;
      hence thesis by A10,A39,TARSKI:def 2;
    end;
    suppose
      mu=4;
      hence thesis by A17,A39,TARSKI:def 2;
    end;
    suppose
      mu=5;
      hence thesis by A37,A39,TARSKI:def 2;
    end;
  end;
  then
A41: rng (Y_axis(f))={S-bound L~f,N-bound L~f} by A19;
  then card rng (Y_axis(f))=2 by A1,CARD_2:57;
  then
A42: len (Incr (Y_axis(f)))=2 by SEQ_4:def 21;
A43: W-bound L~f < E-bound L~f by SPRECT_1:31;
  then
A44: card rng (X_axis(f))=2 by A35,CARD_2:57;
  then
A45: len (Incr (X_axis(f)))=2 by SEQ_4:def 21;
A46: len GoB(f) = card rng X_axis(f) by GOBOARD2:13
    .=1+1 by A43,A35,CARD_2:57;
  then
A47: 1 in Seg len GoB f by FINSEQ_1:1;
A48: width GoB(f) = card rng Y_axis(f) by GOBOARD2:13
    .=1+1 by A1,A41,CARD_2:57;
  for p being FinSequence of the carrier of TOP-REAL 2 st p in rng GoB f
  holds len p = 2
  proof
    len GoB(Incr(X_axis(f)),Incr(Y_axis(f)) ) =len (Incr(X_axis(f))) by
GOBOARD2:def 1
      .=2 by A44,SEQ_4:def 21;
    then consider s1 being FinSequence such that
A49: s1 in rng GoB(Incr(X_axis(f)),Incr(Y_axis(f)) ) and
A50: len s1 = width GoB(Incr(X_axis(f)),Incr(Y_axis(f)) ) by MATRIX_0:def 3;
    let p be FinSequence of the carrier of TOP-REAL 2;
    consider n being Nat such that
A51: for x st x in rng GoB f ex s being FinSequence st s=x & len s =
    n by MATRIX_0:def 1;
    assume p in rng GoB f;
    then
A52: ex s2 being FinSequence st s2=p & len s2 = n by A51;
    s1 in rng GoB f by A49,GOBOARD2:def 2;
    then ex s being FinSequence st s=s1 & len s = n by A51;
    hence thesis by A48,A50,A52,GOBOARD2:def 2;
  end;
  then
A53: GoB f is Matrix of 2,2,the carrier of TOP-REAL 2 by A46,MATRIX_0:def 2;
A54: 1 in Seg (width GoB f) by A48,FINSEQ_1:1;
  then [1,1] in [:Seg (len GoB f),Seg (width GoB f):] by A47,ZFMISC_1:87;
  then
A55: [1,1] in Indices GoB f by A46,A48,A53,MATRIX_0:24;
A56: width GoB f in Seg (width GoB f) by A48,FINSEQ_1:1;
  then [1,width GoB f] in [:Seg (len GoB f),Seg (width GoB f):] by A47,
ZFMISC_1:87;
  then
A57: [1,width GoB f] in Indices GoB f by A46,A48,A53,MATRIX_0:24;
A58: len GoB f in Seg len GoB f by A46,FINSEQ_1:1;
  then [len GoB f,1] in [:Seg (len GoB f),Seg (width GoB f):] by A54,
ZFMISC_1:87;
  then
A59: [len GoB f,1] in Indices GoB f by A46,A48,A53,MATRIX_0:24;
  (S-max L~f)`1 =(SE-corner D)`1 by SPRECT_1:81
    .=E-bound D
    .=E-bound L~f by SPRECT_1:61
    .=(Incr(X_axis(f))).2 by A43,A36,A45,Th1;
  then
  (S-max L~f)`1 =(|[(Incr(X_axis(f))).2,(Incr(Y_axis(f))).1]|)`1;
  then
A60: (S-max L~f)`1 =((GoB f)*(len (GoB f),1))`1 by A29,A46,A59,GOBOARD2:def 1;
  (S-min L~f)`1 =(SW-corner D)`1 by SPRECT_1:80
    .=W-bound D
    .=W-bound L~f by SPRECT_1:58
    .=(Incr(X_axis(f))).1 by A43,A36,A45,Th1;
  then
  (S-min L~f)`1 =(|[(Incr(X_axis(f))).1,(Incr(Y_axis(f))).1]|)`1;
  then
A61: (S-min L~f)`1 =((GoB f)*(1,1))`1 by A29,A55,GOBOARD2:def 1;
  [len GoB f,width GoB f] in [:Seg (len GoB f),Seg (width GoB f):] by A58,A56,
ZFMISC_1:87;
  then
A62: [len GoB f,width GoB f] in Indices GoB f by A46,A48,A53,MATRIX_0:24;
  W-bound L~f =(Incr(X_axis(f))).1 by A43,A36,A45,Th1;
  then (W-max L~f)`1 =(Incr(X_axis(f))).1;
  then (W-max L~f)`1 =(|[(Incr(X_axis(f))).1,(Incr(Y_axis(f))).(1+1)]|)`1;
  then
A63: (W-max L~f)`1 =((GoB f)*(1,width (GoB f)))`1 by A29,A48,A57,GOBOARD2:def 1
;
A66: rng (Incr (Y_axis(f)))={S-bound L~f,N-bound L~f} by A41,SEQ_4:def 21;
  then
A67: N-bound L~f =(Incr(Y_axis(f))).2 by A1,A42,Th1;
  then (N-min L~f)`2 =(Incr(Y_axis(f))).2;
  then
  (N-min L~f)`2 =(|[(Incr(X_axis(f))).1,(Incr(Y_axis(f))).2]|)`2;
  then
A68: (N-min L~f)`2 =((GoB f)*(1,width (GoB f)))`2 by A29,A48,A57,GOBOARD2:def 1
;
A69: S-bound L~f =(Incr(Y_axis(f))).1 by A1,A66,A42,Th1;
  then (S-min L~f)`2 =(Incr(Y_axis(f))).1;
  then
  (S-min L~f)`2 =(|[(Incr(X_axis(f))).1,(Incr(Y_axis(f))).1]|)`2;
  then
A70: (S-min L~f)`2 =((GoB f)*(1,1))`2 by A29,A55,GOBOARD2:def 1;
  (N-max L~f)`2 =(|[(Incr(X_axis(f))).2,(Incr(Y_axis(f))).2]|)`2 by A67;
  then
A71: (N-max L~f)`2 =((GoB f)*(len (GoB f),width (GoB f)))`2 by A29,A46,A48,A62,
GOBOARD2:def 1;
  (S-max L~f)`2 =(Incr(Y_axis(f))).1 by A69;
  then
  (S-max L~f)`2 =(|[(Incr(X_axis(f))).2,(Incr(Y_axis(f))).1]|)`2;
  then
A72: (S-max L~f)`2 =((GoB f)*(len (GoB f),1))`2 by A29,A46,A59,GOBOARD2:def 1;
  (N-max L~f)`1 =(NE-corner D)`1 by SPRECT_1:77
    .=E-bound D
    .=E-bound L~f by SPRECT_1:61
    .=(Incr(X_axis(f))).2 by A43,A36,A45,Th1;
  then (N-max L~f)`1 =(|[(Incr(X_axis(f))).(1+1),(Incr(Y_axis(f))).(1+1)]|)`1;
  then (N-max L~f)`1 =((GoB f)*(len (GoB f),width (GoB f)))`1 by A29,A46,A48
,A62,GOBOARD2:def 1;
  hence thesis by A11,A23,A9,A6,A14,A3,A46,A48,A63,A60,A61,A68,A71,A72,A70,
EUCLID:53;
end;
