reserve x,y for Element of REAL;
reserve i,j,k for Element of NAT;
reserve a,b for Element of REAL;

theorem Th8:
  not (0,1)-->(a,b) in REAL
proof
  set IR = { A where A is Subset of RAT+: for r being Element of RAT+ st r in
  A holds (for s being Element of RAT+ st s <=' r holds s in A) & ex s being
  Element of RAT+ st s in A & r < s};
  set f = (0,1)-->(a,b);
A1: now
    f = {[0,a],[1,b]} by FUNCT_4:67;
    then
A2: [1,b] in f by TARSKI:def 2;
    assume f in [:{{}},REAL+:];
    then consider x,y being object such that
A3: x in {{}} and
    y in REAL+ and
A4: f = [x,y] by ZFMISC_1:84;
    x = 0 by A3,TARSKI:def 1;
    then per cases by A4,A2,TARSKI:def 2;
    suppose
      {{1,b},{1}} = {0};
      then 0 in {{1,b},{1}} by TARSKI:def 1;
      hence contradiction by TARSKI:def 2;
    end;
    suppose
      {{1,b},{1}} = {0,y};
      then 0 in {{1,b},{1}} by TARSKI:def 2;
      hence contradiction by TARSKI:def 2;
    end;
  end;
A5: f = {[0,a],[1,b]} by FUNCT_4:67;
  now
    assume f in {[i,j]: i,j are_coprime & j <> {}};
    then consider i,j such that
A6: f = [i,j] and
    i,j are_coprime and
    j <> {};
A7: {i} in f & {i,j} in f by A6,TARSKI:def 2;
A8: now
      assume i = j;
      then {i} = {i,j} by ENUMSET1:29;
      then
A9:  [i,j] = {{i}} by ENUMSET1:29;
      then [1,b] in {{i}} by A5,A6,TARSKI:def 2;
      then
A10:  [1,b] = {i} by TARSKI:def 1;
      [0,a] in {{i}} by A5,A6,A9,TARSKI:def 2;
      then [0,a] = {i} by TARSKI:def 1;
      hence contradiction by A10,XTUPLE_0:1;
    end;
    per cases by A5,A7,TARSKI:def 2;
    suppose
      {i,j} = [0,a] & {i} = [0,a];
      hence contradiction by A8,ZFMISC_1:5;
    end;
    suppose that
A11:  {i,j} = [0,a] and
A12:  {i} = [1,b];
      i in {i,j} by TARSKI:def 2;
      then i = {0,a} or i = {0} by A11,TARSKI:def 2;
      then
A13:  0 in i by TARSKI:def 1,def 2;
      i = {1} by A12,Lm4;
      hence contradiction by A13,TARSKI:def 1;
    end;
    suppose that
A14:  {i,j} = [1,b] and
A15:  {i} = [0,a];
      i in {i,j} by TARSKI:def 2;
      then i = {1,b} or i = {1} by A14,TARSKI:def 2;
      then
A16:  1 in i by TARSKI:def 1,def 2;
      i = {0} by A15,Lm4;
      hence contradiction by A16,TARSKI:def 1;
    end;
    suppose
      {i,j} = [1,b] & {i} = [1,b];
      hence contradiction by A8,ZFMISC_1:5;
    end;
  end;
  then
A17: not f in {[i,j]: i,j are_coprime & j <> {}} \ the set of all [k,1];
  not ex x,y being set st {[0,x],[1,y]} in IR
  proof
    given x,y being set such that
A18: {[0,x],[1,y]} in IR;
    consider A being Subset of RAT+ such that
A19: {[0,x],[1,y]} = A and
A20: for r being Element of RAT+ st r in A holds (for s being Element
of RAT+ st s <=' r holds s in A) & ex s being Element of RAT+ st s in A & r < s
    by A18;
    [0,x] in A & for r,s being Element of RAT+ st r in A & s <=' r holds
    s in A by A19,A20,TARSKI:def 2;
    then consider r1,r2,r3 being Element of RAT+ such that
A21: r1 in A and
A22: r2 in A and
A23: r3 in A & r1 <> r2 & r2 <> r3 & r3 <> r1 by ARYTM_3:75;
A24: r2 = [0,x] or r2 = [1,y] by A19,A22,TARSKI:def 2;
    r1 = [0,x] or r1 = [1,y] by A19,A21,TARSKI:def 2;
    hence contradiction by A19,A23,A24,TARSKI:def 2;
  end;
  then
A25: not f in DEDEKIND_CUTS by A5,ARYTM_2:def 1;
  now
    assume f in omega;
    then {} in f by ORDINAL3:8;
    hence contradiction by A5,TARSKI:def 2;
  end;
  then not f in RAT+ by A17,XBOOLE_0:def 3;
  then not f in REAL+ by A25,ARYTM_2:def 2,XBOOLE_0:def 3;
  hence thesis by A1,XBOOLE_0:def 3;
end;
