reserve Y for non empty set;

theorem
  for a,b,c being Function of Y,BOOLEAN holds (a 'imp' c) 'imp' ((
  b 'imp' c) 'imp' ((a 'or' b) 'imp' c))=I_el(Y)
proof
  let a,b,c be Function of Y,BOOLEAN;
  for x being Element of Y holds ((a 'imp' c) 'imp' ((b 'imp' c) 'imp' ((a
  'or' b) 'imp' c))).x=TRUE
  proof
    let x be Element of Y;
    ((a 'imp' c) 'imp' ((b 'imp' c) 'imp' ((a 'or' b) 'imp' c))).x ='not'
(a 'imp' c).x 'or' ((b 'imp' c) 'imp' ((a 'or' b) 'imp' c)).x by BVFUNC_1:def 8
      .='not'( 'not' a.x 'or' c.x) 'or' ((b 'imp' c) 'imp' ((a 'or' b)
    'imp' c)).x by BVFUNC_1:def 8
      .='not'( 'not' a.x 'or' c.x) 'or' ('not' (b 'imp' c).x 'or' ((a
    'or' b) 'imp' c).x) by BVFUNC_1:def 8
      .='not'( 'not' a.x 'or' c.x) 'or' ('not'( 'not' b.x 'or' c.x)
    'or' ((a 'or' b) 'imp' c).x) by BVFUNC_1:def 8
      .='not'( 'not' a.x 'or' c.x) 'or' ('not'( 'not' b.x 'or' c.x)
    'or' ('not' (a 'or' b).x 'or' c.x)) by BVFUNC_1:def 8
      .='not'( 'not' a.x 'or' c.x) 'or' ('not'( 'not' b.x 'or' c.x)
    'or' ('not' (a.x 'or' b.x) 'or' c.x)) by BVFUNC_1:def 4
      .='not'( 'not' a.x 'or' c.x) 'or' ('not'( 'not' b.x 'or' c.x)
    'or' ((c.x 'or' 'not' a.x) '&' ('not' b.x 'or' c.x))) by XBOOLEAN:9
      .='not'( 'not' a.x 'or' c.x) 'or' (('not'( 'not' b.x 'or' c.x)
'or' (c.x 'or' 'not' a.x)) '&' ('not'( 'not' b.x 'or' c.x) 'or' ('not'
    b.x 'or' c.x))) by XBOOLEAN:9
      .='not'( 'not' a.x 'or' c.x) 'or' (TRUE '&' ('not'( 'not' b.x
    'or' c.x) 'or' (c.x 'or' 'not' a.x))) by XBOOLEAN:102
      .='not'( 'not' a.x 'or' c.x) 'or' ('not'( 'not' b.x 'or' c.x)
    'or' ('not' a.x 'or' c.x))
      .=('not'( 'not' a.x 'or' c.x) 'or' ('not' a.x 'or' c.x)) 'or'
    'not'( 'not' b.x 'or' c.x)
      .=TRUE 'or' 'not'( 'not' b.x 'or' c.x) by XBOOLEAN:102
      .=TRUE;
    hence thesis;
  end;
  hence thesis by BVFUNC_1:def 11;
end;
